"The Enigma of the Old Manor House" by "Daniel M. Stelzer"

Volume -1 - Logistics

The story headline is "An Interactive Mystery".
The story genre is "Mystery".
The release number is 2.
The story description is "Everyone's heard stories about the old mansion on the hill. Decades ago, they say, old Doctor Black lived up there all alone. Until something happened—nobody knows what—and he vanished without a trace. The house belongs to the Historical Society now, it's turned into a little sort of local museum. But the south wing has always been closed to the public, and they say that's where it happened. Where he was murdered.

You don't really *believe* in the ghost stories any more, of course. You're too old for that. He probably just had a heart attack. But it *is* Halloween coming up, and Abby started telling the story, and you'd read that book and you told her it sounded like a *poltergeist*, a ghost that throws things around. Which means it has to be real and physical, right? Something you could find and trap.

And then Dylan made it a *dare* and nobody wanted to back down. And that's how you ended up here, in the dead of night on Halloween, prying one of the boards off the window next to the door and squirming your way in.

None of the others showed up. But you are *not* afraid of ghost stories, and you are *not* going to chicken out like your friends did. One way or another, you're determined to find out the truth, just like the detectives in the books always do."

Release along with source text, cover art ("the title superimposed over an old, ivy-covered house"), an "ECTOCOMP" website, a "Parchment" interpreter, a file of "Hints" called "hints.html", and a file of "Extensions" called "extensions.zip".

Include Hacked Easy Doors by Daniel Stelzer.
Include Implicit Actions by Eric Eve.
Include Formatting Capture by Daniel Stelzer.
Include Scopability by Brady Garvin.
Include Typographical Conveniences by Daniel Stelzer.
Include Integrated Tutorial by Daniel Stelzer.
Include Epistemology by Eric Eve.
Include Basic Screen Effects by Emily Short.
Include Small Kindnesses by Aaron Reed.

Rule for constructing the status line:
	if the turn count is one, do nothing;
	[deepen status line to one rows;]
	otherwise center "[location]" at row 1.

Use scoring, American dialect, memory economy, and the serial comma.

Volume 0 - Mechanics

Part Doors

Door-directionality relates a door (called the door-in-question) to a direction (called the direction-in-question) when the room-or-door direction-in-question from the location is the door-in-question. The verb to lead toward means the door-directionality relation. The verb to lead through means the reversed door-directionality relation.

Understand "[something related by door-directionality]" as a door. [Understand "east door" for disambiguation purposes]

An internal-door is a kind of door. The matching key of an internal-door is usually no-key. The printed name of an internal-door is usually "door". Understand "door" or "door to" or "door to the" as an internal-door. An internal-door is usually closed, openable, unlocked, lockable, not scenery, and not proper-named.
After printing the name of an internal-door:
	let the way be a random direction that leads through the item described;
	say " to [the way]".

[A first-door is an internal-door. It is south of Alpha and north of Beta. A second-door is an internal-door. It is west of Alpha and east of Delta.
A ladder is an enterable portable supporter in Alpha. A box is an open container in Beta.]

Liminality relates a door (called X) to a room (called Y) when the front side of X is Y or the back side of X is Y. The verb to be a threshold of implies the liminality relation. The verb to be liminal to implies the liminality relation.
To decide whether a door connects (X - a room) and (Y - a room):
	repeat with D running through doors liminal to X:
		if the other side of D from X is Y, yes;
	no.
Proximity relates a room (called X) to a room (called Y) when a door connects X and Y. The verb to be near implies the proximity relation. Definition: a room is nearby if it is near the location.
[After looking: say "Adjacent rooms are [the list of rooms near the location]."; continue the action.]

To describe (the portal - an internal-door) with (caps - a truth state) capitalization and (same - a truth state) similarity:
	say "[if caps is true]A[else]a[end if]";
	if the portal is jammed:
		say "[if same is true]nother[end if]";
	else if the portal is open:
		say "n[if same is true]other[end if] open";
	otherwise:
		say "[if same is true]nother[end if] closed";
	say " door leads ";
	let the way be a random direction that leads through the portal;
	say "[way]";
	let the destination be the room way from the location;
	if the destination is visited, say " to [the destination]";
	if the portal is jammed, say " (though it looks like something is blocking it)".

Rule for writing a paragraph about an internal-door:
	if there should be darkness:
		say "Faint, grayish rectangles of light stand out in the dark. ";
	let L be the list of internal-doors liminal to the location;
	let P1 be entry 1 in L;
	let P2 be entry 2 in L;
	let same be whether or not (P1 is open and P2 is open) or (P1 is closed and P2 is closed) or P2 is jammed;
	describe P1 with true capitalization and false similarity;
	now P1 is mentioned;
	say ", and ";
	describe P2 with false capitalization and same similarity;
	now P2 is mentioned;
	if the location is the Entrance, say ". The main door of the mansion looms to the south";
	say ".".

Section Hazards

An internal-door can be jammed or unjammed. An internal-door is usually unjammed. A jammed internal-door is usually open.
Instead of opening or closing or bolting or unbolting or pushing or pulling or turning or rubbing a jammed internal-door: say "You put all your weight against the door, but it doesn't budge. It's stuck just a little bit open."
Instead of examining a jammed internal-door:
	if there is a hazard in the location:
		if there should be darkness:
			say "It's blocked from this side, but you can't quite see what it's caught on in the dark.";
		otherwise:
			say "It's blocked by [a random hazard in the location].";
	otherwise:
		say "Something's blocking it from the other side. You can push it about a foot open but no more."
	
Definition: a thing is bulky if it is not the notebook and it is not part of the notebook and it is not the silver key.
Before going through a jammed internal-door when the player carries a bulky thing: say "The door won't open more than about a foot. You might be able to squirm your way in, but not while holding [the list of bulky things carried by the player]." instead.
First before going through a jammed internal-door with something: say "The door won't open more than about a foot, so there's no way [the thing gone with] will fit." instead.
Report going through a jammed internal-door: say "It's a tight fit, but you manage to squirm your way through the opening.".
A hazard is a kind of thing. A hazard can be cleared or uncleared.
Before pulling or turning or rubbing or taking a hazard: try pushing the noun instead.

Part Ladders

Before climbing an enterable thing: try entering the noun instead.

Definition: something is nonenterable if it is not enterable.
Check inserting an enterable thing into a nonenterable container: say "[The noun] [are] way too big to fit." instead.
Check putting an enterable thing on a nonenterable supporter: say "[The noun] [are] way too big to fit." instead.

Part Skylights

The standard entering rule does nothing when the noun is an easydoor.
A skylight is a kind of easydoor. A skylight is always open and not openable. Understand "skylight" as a skylight. The plural of skylight is asdfasdf.
Instead of opening or closing or locking or unlocking or bolting or unbolting or pushing or pulling or turning a skylight: say "You can open it pretty easily, but it falls closed as soon as you let go."
An inside-skylight is a kind of skylight. The dooraction of an inside-skylight is usually "[one of]Perched on [the holder of the player], you shove [the item described] open, then grab hold of the edge and scramble up through [them][or]You pull yourself up through [the item described][stopping].". The printed name of an inside-skylight is usually "skylight".
Before going up in the presence of an inside-skylight (called the window):
	[initialize the implicit action;
	let the previous position be the location;
	finish the implicit action with participle "scrambling through" infinitive "scramble through" object "[the window]" and condition true;
	try entering the window instead;]
	say "(through [the window])[command clarification break]";
	try entering the window instead.
Precondition for entering a carried supporter:
	initialize the implicit action;
	silently try dropping the noun;
	finish the implicit action with participle "setting up" infinitive "set up" object "[the noun]" and condition (whether or not the noun is not carried).
Precondition for entering an inside-skylight when the player is not on the ladder:
	if the ladder is touchable:
		initialize the implicit action;
		silently try entering the ladder;
		finish the implicit action with participle "climbing onto" infinitive "climb onto" object "[the ladder]" and condition (whether or not the player is on the ladder);
	otherwise if the player is not on a supporter and an enterable supporter (called the platform) is touchable:
		initialize the implicit action;
		silently try entering the platform;
		finish the implicit action with participle "climbing onto" infinitive "climb onto" object "[the platform]" and condition (whether or not the player is on the platform);
	if the player is not on the ladder:
		say "It's too high up to reach[if the player is on a supporter], even from [the holder of the player][else] from here[end if]." instead.

The implicitly pass through other barriers rule does nothing when entering an inside-skylight.

An outside-skylight is a kind of skylight. An outside-skylight is usually scenery.
To tumble is a verb.
Instead of inserting something into an outside-skylight:
	say "You drop [the noun] into [the second noun] and [regarding the noun][they] [tumble] down into the room below.";
	move the noun to the outpoint of the second noun.
Before putting something on an outside-skylight: try inserting the noun into the second noun instead.
Before throwing something at an outside-skylight: try inserting the noun into the second noun instead.
Understand "drop [something preferably held] through/down/-- [something]" as throwing it at.

[There is an inside-skylight in Alpha called an a-skylight. It leads to Gamma. There is an outside-skylight in Gamma called an a-skylight-o. It leads to Alpha.
The player carries an apple. The player carries a device called a lantern.]

Part Lighting

Definition: a thing is inaccessible rather than accessible if it is nowhere or it is enclosed by a closed container.

A thing can be lightbound, darkbound, or unbound. A thing is usually unbound.
To decide whether there should be light:
	if the breaker panel is switched on, yes;
	if the location of the lantern is the location and the lantern is switched on and the lantern is accessible, yes; [Using this instead of scope because scope is only recalculated at specific times]
	no.
To decide whether there should not be light:
	if there should be light, no;
	yes.
To decide whether there should be darkness:
	if there should be light, no;
	yes.
To rearrange the set:
	if there should be light:
		now all lightbound things are scopable;
		now all lightbound things are not undescribed;
		now all darkbound things are unscopable;
		now all darkbound things are undescribed;
	otherwise:
		now all darkbound things are scopable;
		now all darkbound things are not undescribed;
		now all lightbound things are unscopable;
		now all lightbound things are undescribed.
Before doing anything with an unscopable thing:
	now the latest parser error is the can't see any such thing error;
	carry out the printing a parser error activity;
	stop the action.
Rule for printing a parser error when the latest parser error is the can't see any such thing error and there should be darkness: say "You feel around, but can't find any such thing in the dark."
Every turn: rearrange the set.
After going: rearrange the set; continue the action.
Before looking: rearrange the set.
When play begins: rearrange the set.

[The moon is a darkbound thing in Alpha.
The sun is a lightbound thing in Alpha.]

[The first-door is jammed.]

Part Hangers

A hanger is a kind of supporter. A hanger is usually fixed in place.
Definition: a thing is hangable rather than unhangable if it is the canvas tarp or it is the wind chimes.
Instead of putting an unhangable thing on a hanger: say "[The second noun] is too narrow to support [the noun]."
Before inserting something into a hanger: try putting the noun on the second noun instead.
The carrying capacity of a hanger is 1.

Volume I - The Map

Part Roof

The Roof is a room. "You've clambered up onto the roof of the manor, perched on the flat part around the central dome. It's only about a foot and a half wide, and you find yourself clinging to the dome until your knuckles turn white, trying not to lose your grip."

To say roofdirs:
	say "You came up from the ";
	if the location of the ladder is:
		-- the Kitchen: say "northwest";
		-- the Sunroom: say "northeast";
		-- the Sitting Room: say "southwest";
		-- the Study: say "southeast";
		-- otherwise: say "ERROR where is the ladder?".

The northwest skylight is an outside-skylight in the Roof. It leads to the Kitchen. The dooraction is "[if the ladder is in the Kitchen]You clamber down onto the ladder, then down to the floor[else]You squirm your way down through the skylight, grabbing onto one of the taller cabinets and hopping awkwardly down onto the countertop[end if]." The description is "[if the Kitchen is visited]This one leads down to the kitchen[otherwise]Down below you see only darkness[end if]." Understand "nw" as the northwest skylight.
The northeast skylight is an outside-skylight in the Roof. It leads to the Sunroom. The dooraction is "[if the ladder is in the Sunroom]You clamber down onto the ladder, then down to the floor[else]You wriggle down through the skylight, trying to hang onto the edge as long as you can, then fall and land with a [i]whump[/i] on the ground[end if]." The description is "[if the Sunroom is visited]This one leads down to the sunroom[otherwise]Down below you see a small sunroom[end if]." Understand "ne" as the northeast skylight.
The southeast skylight is an outside-skylight in the Roof. It leads to the Study. The dooraction is "[if the ladder is in the Study]You clamber down onto the ladder, then down to the floor[else]You pull the skylight open and lower yourself down onto the desk, then sort of scramble-fall down to the floor[end if]." The description is "[if the Study is visited]This one leads down to the study[otherwise]Down below you see only darkness[end if]." Understand "se" as the southeast skylight.
The southwest skylight is an outside-skylight in the Roof. It leads to the Sitting Room. The dooraction is "[if the ladder is in the Sitting Room]You clamber down onto the ladder, then down to the floor[else]From the skylight you're able to climb down onto the wardrobe, then leap down to a couch and tumble off[end if]." The description is "[if the Sitting Room is visited]This one leads down to the sitting room[otherwise]Down below you see only darkness[end if]." Understand "sw" as the southwest skylight.
Some disambig-skylights are fixed in place in the Roof. The printed name is "four skylights". The initial appearance is "Four wide skylights stretch out from your ledge, marking the corners of the mansion.". Instead of entering the disambig-skylights: say "You need to choose one in particular." Instead of inserting something into the disambig-skylights: say "You need to choose one in particular." Understand "skylights" or "skylight" or "four" or "wide" as the disambig-skylights. Does the player mean doing something to the disambig-skylights: it is very likely. The description is "One to the southeast[if the Study is visited], over the study[end if]. One to the southwest[if the Sitting Room is visited], over the sitting room[end if]. One to the northeast[if the Sunroom is visited], over the sunroom[end if]. And one to the northwest[if the Kitchen is visited], over the kitchen[end if]. [roofdirs].".
Instead of dropping something when the location is the Roof: say "[The noun] would probably fall and get lost. You could probably drop [them] into one of the skylights, though."

Before going northwest in the Roof: try entering the northwest skylight instead.
Before going northeast in the Roof: try entering the northeast skylight instead.
Before going southeast in the Roof: try entering the southeast skylight instead.
Before going southwest in the Roof: try entering the southwest skylight instead.
Instead of going down in the Roof: say "There are four skylights leading down, at the four corners. [roofdirs].".
Instead of going nowhere in the Roof: say "The skylights are at the four corners: northeast, southeast, northwest, and southwest. [roofdirs].".
Check listing exits in the Roof:
	say "The skylights are at the four corners: northeast, southeast, northwest, and southwest. [roofdirs].";
	stop the action.

Instead of entering an outside-skylight when the breaker panel is not switched on and the outpoint of the noun is not the location of the ladder: say "You peer down through the skylight, but can't see much in the room below. And you're just a bit too scared to try to drop down without seeing what's underneath. Maybe if you had the ladder, or had a bit more light[--]but you [i]really[/i] don't want to get hurt and trapped here.".

The dome of the roof is scenery in the Roof. The description is "Reassuringly solid." Understand "ledge" and "central" and "flat part" as the dome.

Part Huge Room

The Huge Room is a room. "High and wide and rectangular, big enough that you can hear your footsteps echo back and forth off the walls. It's grand and impressive and makes you feel very small and very much alone. [if there should not be light]You can barely make out anything in the gloom, and more than once you bang your shin on some piece of furniture as you try to navigate through it[else if the breaker panel is switched on]It really seems like it [i]deserves[/i] a chandelier, or several chandeliers, but instead it's lit by a dozen little spotlights shining down from the edges of the ceiling, revealing piles of sheet-covered furniture and long streaks and scuff marks in the wooden floor[else]Your lantern makes a little pool of light around you, but everything past that is lost in darkness; the furniture looms gray and ghostly at the edges of your vision[end if]."

Understand "play [something]" as attacking.
A grand piano is fixed in place in the Huge Room. The initial appearance is "A grand piano stands proudly off to one side." It is a container. It is lightbound, closed, and locked. The tiny silver key unlocks it. The description of the piano is "It's the one piece of furniture here that's not covered with a sheet, maybe because it's already got a cover built into it. It's [if closed]shut tight, with both the strings and the keys hidden away[else]now been opened up to the dusty air[end if]." Understand "cover" as the grand piano.
Instead of opening the locked grand piano: say "It doesn't budge. Looking closer, there's a little silver keyhole on the key cover."
Some piano-keys are fixed in place in the grand piano. The printed name is "keys". Understand "keys" or "ivory" or "ivories" as the piano-keys. The description is "Are these actual ivory?". Instead of pushing or pulling or attacking the piano-keys: say "You play a few notes. It's horrifically out of tune."
Some strings are fixed in place in the grand piano. The description is "They're a lot less dusty than everything else in this house." Instead of pushing or pulling or turning the strings: say "Even if you knew how to tune a piano, you don't have the equipment."
Instead of attacking the closed piano: say "It's closed."
Instead of attacking the open piano: try attacking the piano-keys.
Instead of attacking the strings: try attacking the piano-keys.

A mess of toppled furniture is a lightbound hazard in the Huge Room. "Furniture has been stacked haphazardly all over the room[if uncleared], and some of these stacks have toppled over, turning the east side of the room into an obstacle course and half-blocking the door[else], though you've managed to clear a path through the mess[end if]." Understand "obstacle" and "course" and "stacks" and "stack" as the mess of toppled furniture.
Instead of pushing the mess of toppled furniture:
	if the noun is uncleared:
		say "You do your best to drag some of the pieces away from the door, making a path through the mess.";
		now the noun is cleared;
		now the jam1 is unjammed;
	otherwise:
		say "You haul a couple more pieces around, but it barely makes an impact on the mess."

Part Sunroom

The Sunroom is a room. "Moonlight streams in through the glass walls and ceiling, filling the room with a cold, silvery sort of glow. This must be the one room in the mansion that wasn't boarded up; it looks like a tiny greenhouse, and these shelves must have been full of plants at some point. Now they're all empty and bare. Like a skeleton of what used to be."

Understand "ring [something]" as attacking.
A little hook is a hanger in the Sunroom.
A mess of broken shards is fixed in place in the Sunroom. "A big pile of dirt and broken clay covers the floor[if the hook is not mentioned] under a [little hook], where something must have been hanging[end if]." The description of the shards is "Messy and very sharp, with all the broken bits of clay[if the chimes are off-stage]. Something glimmers under the dirt[end if]." Understand "glimmer" or "dirt" or "clay" or "bits" or "pile" or "shard" as the mess of shards.
Instead of searching or pushing or pulling or turning or rubbing or taking or looking under the shards:
	if the gloves are not worn:
		say "[one of]You sift through some of the dirt, until a shard catches the side of your finger and draws blood. Ouch![or]You don't really want [i]more[/i] cuts right now.[stopping]";
	otherwise if the chimes are off-stage:
		say "You sift your hands through the dirt and shards until suddenly something clinks. You pull it out: it looks like a little set of wind chimes.";
		now the player carries the chimes;
	otherwise:
		say "You sift through the dirt some more, but there's nothing else to find."
Some wind chimes are a thing. The description of the wind chimes is "Remarkably shiny, even when they're covered in dirt. They make a little ringing sound as they bump against each other."
Instead of attacking or touching or rubbing the chimes: say "You tap one of the chimes and it plays a high, clear [one of]F sharp[or]B[purely at random]."
Rule for writing a paragraph about a hanger which supports the chimes:
	say "Some [wind chimes] hang from [the holder of the chimes], silent in the still air.".

A sunroom-skylight is an inside-skylight in the Sunroom. It leads to the Roof. The initial appearance is "One of the panes in the roof is set on hinges, to act as a skylight." The description is "It looks like this one pane is meant to open, maybe for ventilation?" Understand "pane" and "hinge" and "hinges" as the sunroom-skylight.

Part Library

The Library is a room. "[if there should not be light]You can feel more than see the tall, imposing bookshelves all around, as if they're closing in on you in the gloom. You move carefully, trying not to trip on any wayward books[otherwise]The walls of this room are lined with wooden bookshelves, sagging under the weight of the books they once held[end if]."

Some shelves are a supporter in the library. They are scenery. Understand "bookshelves" or "book shelf" or "book shelves" or "shelf" or "bookshelf" or "wooden" or "sagging" as the shelves.
A ladder is an enterable supporter in the Library. It is pushable between rooms. "A wheeled ladder stands in the corner." The description of the ladder is "It's old, but it looks sturdy. The solid base and four wheels mean it doesn't have to actually lean against the shelves for support." Instead of pushing or pulling or turning or taking the ladder: say "It's too heavy to lift, but you can push it around pretty well."
After going with the ladder:
	say "You push the ladder ahead of you...";
	continue the action.

A heap of books is fixed in place in the Library. "The books lie all in a heap on the floor, like someone's been throwing them around." The description of the heap of books is "There are dozens and dozens of them all over the ground, their spines bent and their pages torn." Understand "pile" or "book" as the heap. It is ambiguously plural and lightbound.
An armload of books is a thing. The description of the armload of books is "You open one of them:[br][i]This game was tested by[br][t]Andrew Schultz[br][t]Mike Russo[br][t]Amanda B[br][t]Sarah Stelzer[br][t]Ada Stelzer[br][t]Grace Foster[br][t]Matt[br][t]Wallace[br][t]Elisabeth[br][t]Jeff (Fos1)[br][t]Nils Fagerburg[br][t]Zed Lopez[br]Post-comp fixes suggested by[br][t]Mathbrush[br]Thank you for playing![/i]".
Does the player mean doing something to the armload of books: it is likely. Understand "book" as the armload. It is ambiguously plural.
Some shelved books are a thing. "Thanks to your valiant efforts, some of the books have been reshelved." They are fixed in place. The description of the shelved books is "They're not organized at all, but at least they're not just heaped on the floor." Understand "book" as the shelved books. They are ambiguously plural.
Before going from the Library when the armload of books is carried: try dropping the armload.
Instead of putting the armload on the ladder: say "The steps aren't quite wide enough for that; the books would just scatter everywhere."
After dropping the armload of books:
	say "You let the books fall back into the heap.";
	remove the armload from play.
Instead of taking or searching the heap:
	say "You scoop up some[if the armload is carried] more[end if] books from the pile.";
	now the armload is carried by the player;
	set pronouns from the armload.
Instead of taking or searching the shelved books:
	say "You scoop up some books from the shelves.";
	now the armload is carried by the player.
Instead of putting the armload on the shelves:
	say "You do your best to put [if the shelved books are on the shelves]some more[else]the[end if] books back on the shelves, making the library look a bit more like a library again.";
	now the shelved books are on the shelves;
	remove the armload from play.

Part Study

The Study is a room. "[if there should be darkness]This room feels small and bare, the sort of place meant for a single person to do work. The carpet is soft under your feet[else]This room feels comfortable and uncomfortable at the same time. The carpet is soft under your feet, and it's all arranged in a way that feels nice and home-y[--]but at the same time, something is missing. All the little decorations and possessions that would make this [i]someone's[/i] study in particular are gone, leaving a sort of empty shell behind[end if]."

The old carpet is scenery in the Study. The description is "Old and stained, but still nice and soft." Understand "stained" or "nice" or "soft" as the carpet.

An old desk is fixed in place in the Study. "An old, well-worn desk stands in one corner, lit by a single square of moonlight coming through the skylight[if there should be light]. It looks like it would be a good place to work if it had a proper chair[else]. Everything except the top is invisible in the darkness[end if]." The description of the desk is "It's an odd sort of pentagon shape, designed to fit into the corner and extend a bit along each wall[if there should be light]. The way the drawers are arranged is probably supposed to make them easy to reach[end if]."
The top of the desk is an enterable supporter. It is part of the old desk.
Some desk drawers is a closed openable lightbound container. They are part of the old desk. Understand "drawer" as the drawers.
Before climbing or entering the desk: try entering the top of the desk instead.
Before putting something on the desk: try putting the noun on the top of the desk instead.
Before inserting something into the desk when the drawers are scopable: try inserting the noun into the drawers instead.
Before opening the desk when the drawers are scopable: try opening the drawers instead.
Before closing the desk when the drawers are scopable: try closing the drawers instead.
Instead of opening or closing the desk: say "It probably has a drawer or something, but you can't find it in the dark."
A tiny silver key is a key in the desk drawers. The plural of key is asdfasdf.
Before searching the old desk:
	if there should be light:
		say "(searching the top)[command clarification break]";
		try searching the top of the desk;
		say "(searching the drawers)[command clarification break]";
		try searching the desk drawers;
		stop the action;
	otherwise:
		say "(feeling around the top)[command clarification break]";
		try searching the top of the desk;
		stop the action.

A study-skylight is an inside-skylight in the Study. It leads to the Roof. It is scenery. The description is "Placed just right to illuminate the desk, and maybe let in some fresh air."

A grandfather clock is a lightbound container in the Study. "A grandfather clock is placed against the opposite wall." It is closed, locked, openable, and fixed in place. The tiny silver key unlocks it. The description of the clock is "It's not ticking any more; the hands have stopped forever at 7:30. The front of the case is currently [if closed]closed[else]open[end if]."
Instead of opening the locked clock: say "You tug on the case, but nothing happens. Looking closer, there seems to be a tiny keyhole under the face."
After opening the clock: say "You pull the front of the clock open, revealing the pendulum inside. The movement makes it rock from side to side and the clock ticks loudly for a few seconds."
Understand "face" or "case" or "front" or "hands" or "hand" or "keyhole" or "tiny keyhole" as the clock.
The pendulum is fixed in place in the clock. The description is "It hangs still and silent."
Instead of pushing or pulling or turning the pendulum: say "You give it a shove and it ticks loudly for a few seconds before falling still again."

Part Entrance

The Entrance is a room. "The entrance hall of the mansion rises up around you, feeling very old and very still. Very...dead. Dust hangs thick in the air and [if there should not be light]dim shapes loom all around[else if the breaker panel is switched on]the odd shadows from the chandelier cross and intersect in a wild pattern across the floor[else]the shadows from your lantern dance and waver as you move[end if]. [if there should be light]The remains of a once-grand staircase lead off to the north, but they're nothing but splinters after the first few steps[else]To the north is nothing but a great dark void[end if]."
The player is in the Entrance.

Instead of going north in the Entrance:
	if there should be darkness, say "You feel blindly in that direction for a moment, but scramble back the moment you feel something scrape against your arm.";
	otherwise say "The staircase is in ruins and past it you can't see anything but broken beams and wire. Whatever lies in the middle part of the mansion, it's off-limits to you. (Hopefully that's not where the ghost is...)".

A fancy chandelier is a hanger in the Entrance. It is lightbound and fixed in place. The chandelier can be shrouded or unshrouded. The chandelier is shrouded. The initial appearance of the chandelier is "[if shrouded]A chandelier hangs down above you, swaddled by a tarp and looking like some sort of massive jellyfish[else if the breaker panel is switched on]A fancy chandelier hangs from the ceiling, shining with brilliant light[else]A fancy chandelier hangs from the ceiling, its crystals shining in the lantern light[end if]." The description of the chandelier is "[if shrouded]It's hard to make out its shape through the canvas[else]'Fancy' doesn't seem like a fancy enough word for it[end if]."
A canvas tarp is part of the fancy chandelier. It is portable. The description of the tarp is "[if the tarp is part of the chandelier]It's loosely wrapped, with the edges of the cloth hanging down above your head[else]A big, loose piece of cloth, a bit smaller than a bedsheet[end if]."
Before pushing or pulling or turning the tarp when the tarp is part of the chandelier: try taking the tarp instead.
Precondition for taking the tarp when the tarp is part of the chandelier and the player is not on the ladder:
	if the ladder is touchable:
		initialize the implicit action;
		silently try entering the ladder;
		finish the implicit action with participle "climbing onto" infinitive "climb onto" object "[the ladder]" and condition (whether or not the player is on the ladder);
	if the player is not on the ladder:
		say "It's too high for you to reach." instead.
Instead of taking the tarp when the tarp is part of the chandelier:
	say "You grab hold of the tarp and carefully unwind it, sending it drifting down to the floor. The chandelier makes a pretty sort of tinkling noise as it sways back and forth.";
	move the tarp to the Entrance;
	now the chandelier is unshrouded.
Rule for writing a paragraph about the tarp when the tarp is not part of the chandelier: say "A canvas tarp lies in a heap on the ground."
Rule for writing a paragraph about a hanger that supports the tarp: say "A [canvas tarp] hangs down from [the holder of the tarp]."

Instead of pushing or pulling or turning or climbing or entering or swinging the chandelier: say "That seems exciting and adventurous and also like a great way to fall and get impaled by lots of pieces of metal and broken crystal."
Instead of singing in the presence of the scopable chandelier: say "That probably won't bring the chandelier down on you like in [i]Phantom of the Opera[/i]...but better not to risk it."

The ruined staircase is lightbound scenery in the Entrance. Understand "stairs" and "stair" as the ruined staircase. The description is "Way too dangerous for you to even go near." Instead of entering or climbing the staircase, try going north.

Part Sitting Room

The Sitting Room is a room. "The huge windows and overhead skylight would normally make this room look nice and comfortable, but they're all boarded over from the outside, turning it all vaguely menacing instead. [if the breaker panel is not switched on]Pale slivers of moonlight shine in from between the boards[else]The overhead lights drown out the bits of moonlight and just make it all look flat, like a movie set[end if]."

A huge wardrobe is a closed openable locked enterable container in the Sitting Room. It is fixed in place. The tiny silver key unlocks it. The wardrobe is lightbound. The initial appearance of the wardrobe is "A huge wardrobe (or maybe it's an 'armoire'?) leans back against the wall." The description of the wardrobe is "One of its legs seems to have given out, making it lean like this. It's currently [if closed]closed[else]open[end if]."
Instead of opening the locked huge wardrobe: say "You tug on the handles, but nothing happens. It must be locked[--]there's a little silver keyhole on the front."
Understand "little" or "silver" or "keyhole" or "handle" or "handles" or "armoire" as the wardrobe.
Instead of pushing or pulling or turning the wardrobe: say "You shove it, but it doesn't fall. Which is probably a good thing, with you right here next to it."
A curtain rod is a hanger in the Sitting Room. "A few tattered scraps of fabric hang from the curtain rods over the windows, the remains of what must have once been some sort of drapery." Understand "drape" or "drapes" or "drapery" or "fabric" or "scraps" or "scraps of" or "tattered" or "rods" or "curtains" as the rod. It is lightbound.
A pair of gloves is in the wardrobe. It is wearable. It is ambiguously plural. The description is "Very old and kind of stiff."

A sitting-room-skylight is an inside-skylight in the Sitting Room. It leads to the Roof. It is scenery. The description is "The glass has been covered up, but it looks like it could still open, if you pushed on it right."
Some boarded windows are scenery in the Sitting Room.  Understand "boards" and "board" or "window" as the boarded windows. The description is "Were the boards meant to keep people out...or to keep someone in?"

Part Dining Room

The Dining Room is a room. "[if there should be darkness]Stacks and stacks of boxes loom all around you as you feel your way forward, threatening to topple over at any moment. You try to focus on your steps, try not to trip, try not to imagine what would happen if you crashed into something and brought them all down on top of you..[otherwise]The big table in the middle shows that this used to be a dining room, but it's more of a storage space now, full to the gills with taped cardboard boxes. This must be where everything else from the manor was put, all shoved in here and forgotten about[end if]."

A big table is an enterable supporter in the Dining Room. It is scenery.

A mess of fallen boxes is a hazard in the Dining Room. It is lightbound. "At least one of those stacks has fallen over[if cleared], though you've managed to clear a path through it to the door[else], completely blocking the south door[end if]." Understand "stack" and "stacks" as the mess of fallen boxes.
Instead of pushing the mess of fallen boxes:
	if the noun is uncleared:
		say "You do your best to stack some of the boxes back up, making a path through the mess.";
		now the noun is cleared;
		now the jam2 is unjammed;
	otherwise:
		say "You haul a couple more boxes out of the way."
Instead of opening or searching the boxes: say "They're quite securely sealed up."

Part Kitchen

The Kitchen is a room. "[if there should be darkness]You can feel counters all around you, a sink, some sort of furniture[else]This room feels different from the rest of the mansion. Simple and empty and kind of sterile. A place you could imagine was part of a living house, if not for all the dust. And the silence[end if]."

Some cabinets are a closed openable container in the Kitchen. They are fixed in place. "A row of cabinets stands above the sink." They are lightbound. Understand "row" or "row of" or "cabinet" as the cabinets. The description of the cabinets is "The hinges look rusty, but still functional." Understand "hinge" or "hinges" as the cabinets.
After opening or closing the cabinets:
	say "The hinges make an awful squeal as you move them.";
	continue the action.
Some shattered china is in the cabinets. It is fixed in place. [Instead of taking the shattered china: say "It would be hard to take any of it without just hurting your hands."] It is not plural-named. The indefinite article is "some".
Some intact china is in the cabinets. Understand "cup" and "saucer" as the intact china. The description is "A matching cup and saucer that have somehow remained intact." It is not plural-named. The indefinite article is "some".
Instead of taking something when the gloves are not worn and the noun is in the cabinets: say "The cabinets are full of little bits and shards, and getting splinters of porcelain in your hands sounds just awful."

A breaker panel is a device in the Kitchen. It is fixed in place and lightbound and not scenery. The initial appearance is "[if switched off]In the lamplight, you can make out a metal box off in the corner. A big lever on the front is switched off[else]The breaker panel is clear and easy to see in the fluorescent light[end if]." Understand "metal" or "box" or "lever" or "big lever" as the breaker panel.
Before turning or pushing or pulling the breaker panel:
	if the noun is switched on, try switching off the noun instead;
	otherwise try switching on the noun instead.
After switching on the breaker panel:
	say "The lever is stiff and hard to move, but you push with all your strength, and all of a sudden it snaps over to the other side. There's a [i]hiss[/i] and then a [i]snap[/i] and then all of a sudden there's light everywhere. This must control all the electricity in the mansion, or at least in this wing.";
	try looking.
After switching off the breaker panel:
	say "You snap the lever back to where it was, and everything goes dark again.";
	try looking. 

A kitchen-skylight is an inside-skylight in the Kitchen. It leads to the Roof. The initial appearance is "A lone skylight casts a square of illumination on the floor[if the breaker panel is switched on], mostly drowned out by the fluorescent lights[end if]." The description is "Out of reach above the sink." Understand "lone" as the kitchen-skylight.

A sink is scenery in the Kitchen. The description is "It hasn't been used in ages." Instead of turning or pushing or pulling or switching on or switching off the sink: say "You twist the faucet, but nothing happens."
Some counters are an enterable supporter in the Kitchen. They are scenery. Understand "counter" as the counters.

Part Outside

The Outdoors is a room.

The main door of the mansion is a scenery door. It is south of the Entrance and north of the Outdoors. It is closed and locked.
Before unbolting or unlocking or opening the main door: refuse to leave instead.
Before going through the main door: refuse to leave instead.
To refuse to leave:
	if the number of visited rooms is less than three:
		say "You can't leave yet!";
	else:
		say "[if the ghost is friendly]It's time to go[else]You can't take any more of this[end if]. You push the door open and hurry out of the mansion. Will anyone believe your story? You're not sure. But one thing is certain: you'll remember what happened, and what you've seen[if the ghost is friendly]. And the new friend you made[end if].";
		end the story.

Part Doors

The door1 is an internal-door. It is east of the Kitchen and west of the Huge Room. It is open.
The door2 is an internal-door. It is south of the Sunroom and north of the Library.
The door3 is an internal-door. It is south of the Library and north of the Study.
The door4 is an internal-door. It is west of the Study and east of the Entrance.
The door5 is an internal-door. It is west of the Entrance and east of the Sitting Room.
The door6 is an internal-door. It is north of the Dining Room and south of the Kitchen. It is open.
The jam1 is a jammed internal-door. It is east of the Huge Room and west of the Sunroom.
The jam2 is a jammed internal-door. It is north of the Sitting Room and south of the Dining Room.

Index map with Roof mapped north of Entrance.

Volume II - The Ghost

Part Descriptions

Definition: a room is hauntable:
	if it is the location of the wind chimes and the wind chimes are on a hanger, yes;
	if it is the location of the canvas tarp and the canvas tarp is on a hanger, yes;
	if it is the location of the intact china and the intact china is accessible, yes;
	if it is the Entrance and the chandelier is unshrouded, yes;
	if it is the Study and the pendulum is accessible, yes;
	if it is the Library and the shelved books are accessible, yes;
	if it is the Huge Room and the piano-keys are accessible, yes;
	if it is the Kitchen and the cabinets are open, yes;
	no.

Onetimesay is initially false. [This is a terribly inelegant way to do this, but I'm on a deadline]
To describe the haunting of (place - a room):
	if the place is the location of the wind chimes and the wind chimes are on a hanger:
		say "The sound of wind chimes echoes through the mansion.[p]";
	if the place is the location of the canvas tarp and the canvas tarp is on a hanger:
		say "You hear the sound of someone pulling and tearing at cloth.[p]";
	if the place is the location of the intact china and the intact china is accessible:
		say "You suddenly hear an odd rattling and clinking sound of china being shaken.[p]";
	if the place is the Entrance and the chandelier is unshrouded:
		say "You hear the sound of swaying metal and tinkling crystal.[p]";
	if the place is the Study and the pendulum is accessible:
		say "The ticking of a clock echoes through the mansion, sharp and quick.[p]";
	if the place is the Library and the shelved books are accessible:
		say "You hear a loud fluttering [i]thump[/i] as something falls from a shelf.[p]";
	if the place is the Huge Room and the piano-keys are accessible:
		say "The mansion is briefly filled with a harsh, discordant piano melody.[p]";
	if the place is the Kitchen and the cabinets are open:
		say "You hear the squeaking of rusty hinges from somewhere.[p]";
	if the place is not hauntable and locatetask is complete and onetimesay is false:
		say "You hear...nothing. The ghost must not be near any of your ghost detectors any more.";
		now onetimesay is true.

The ghost is an undescribed person in the Kitchen. The ghost has an object called the last used door.
Definition: a door is player-leading if the other side of it from the location of the ghost is the location of the player and the player is accessible.
Definition: a door is ghost-viable if it is an internal-door and it is liminal to the location of the ghost and it is open and it is not jammed and it is not player-leading.
The ghost can be wild, wary, tame, or friendly (this is its ferocity). The ghost is wild.
Definition: a container is ghost-usable if it is open and it is in the location of the ghost and there is a portable thing in it and the player is not in it.
[Instead of doing anything when the noun is the ghost or the second noun is the ghost: say "You think the ghost is in here somewhere, but you certainly can't see it. You'll have to approach it a bit less directly, or maybe confine it more somehow."]
Instead of touching or kissing the friendly ghost: say "It feels like air. But also comfortable somehow."
Understand "pet [something]" as touching.
Understand "faint" or "swirl" or "gust" or "air" or "of air" as the ghost.
Understand "cat" or "kitten" or "form" or "cat-like" or "catlike" or "cat like" or "friend" as the ghost when the ghost is tame or the ghost is friendly.
The ghost can be noticed or unnoticed. The ghost is unnoticed.

After the ghost going through a door:
	now the last used door of the ghost is the door gone through;
	say run paragraph on;
	stop the action.
Definition: a door is not-last-used if it is not the last used door of the ghost.

Part Behavior

To do the wild haunt:
	if the location of the ghost is the location of the player:
		let the escape be a random ghost-viable door;
		if the escape is nothing:
			say "You feel a swirl of air around you as if something is trying to escape! After a very frightening minute it seems to settle down again. Watching and waiting for something.";
			now the ghost is wary;
			stop;
		else:
			say "You feel a sudden gust of air rush past you, out through [the escape].";
			silently try the ghost entering the escape;
			now the ghost is noticed;
	otherwise:
		let N be the number of ghost-viable doors;
		if N is zero:
			do nothing;
			[Trapped!]
		otherwise if N is one:
			if a random chance of 3 in 4 succeeds:
				let the passage be a random ghost-viable door;
				silently try the ghost entering the passage;
			else: [stay still]
				stop;
		otherwise if N is two:
			let X be a random number between 1 and 6;
			if X is 1 or X is 2:
				if the last used door of the ghost is a ghost-viable door:
					silently try the ghost entering the last used door of the ghost;
				otherwise:
					silently try the ghost entering a random ghost-viable door;
			else if X is 3 or X is 4 or X is 5:
				silently try the ghost entering a random ghost-viable not-last-used door;
			else: [stay still]
				stop;
	describe the haunting of the location of the ghost.

To do the wary haunt:
	if the location of the ghost is not the location, stop;
	if the ghost is in a closed container:
		say "There's a furious scrabbling and scratching at the inside of [the holder of the ghost] as it tries to tear itself free! For a moment it seems like it might actually escape and take its revenge[--]then it goes quieter.[p]From [the holder of the ghost] you hear a faint but definite 'mrow?'.";
		now the ghost is tame;
	otherwise if there is a ghost-viable door (called the escape):
		say "Seeing [the escape], the swirl of air vanishes through it.";
		try the ghost entering the escape;
		now the ghost is wild;
	otherwise if the ghost is in a container:
		say "The air swirls back out of [the holder of the ghost].";
		move the ghost to the location of the holder of the ghost;
	otherwise if there is a ghost-usable container (called the item):
		say "The air swirls around [the item], then into it, examining [the random thing in the item].";
		move the ghost to the item;
	otherwise:
		say "You hear no sound from the ghost. It's silent now. Waiting. Watching."

To do the tame haunt:
	if the location of the ghost is not the location, stop;
	if the ghost is in a closed container:
		say "There's a faint, plaintive meowing and scratching from inside [the holder of the ghost].";
	otherwise if the ghost is in an open container:
		say "A faint swirl of air slinks out of [the holder of the ghost] and stalks around the room.";
		move the ghost to the location of the holder of the ghost;
	otherwise:
		say "A cat-like form slinks around your ankles, then vanishes again.".

To do the friendly haunt:
	move the ghost to the location;
	say "You can feel the ghost of the cat slinking around you playfully. It seems you've made a friend."

Every turn:
	[say "Ghost start [holder of the ghost].";]
	if the ghost is wild:
		do the wild haunt;
	else if the ghost is wary:
		do the wary haunt;
	else if the ghost is tame:
		do the tame haunt;
	else if the ghost is friendly:
		do the friendly haunt;
	[say "Ghost end [holder of the ghost].";
	say "Condition: [ferocity of the ghost].";]

Volume III - The Notebook and Lantern

Part Possessions

A notebook is in the Entrance. It is not proper-named. The indefinite article is "your".
A lantern is a device in the Entrance. It is not proper-named. The indefinite article is "your".
Definition: a thing is personal rather than impersonal if it is the notebook or it is the lantern.
Definition: a thing is unhandled if it is not handled.
Rule for writing a paragraph about an unhandled personal thing:
	say "Your possessions lie scattered all over the floor, where they fell during your daring entrance. You see [a list of personal things in the location] amid the dust."

The description of the lantern is "A rugged little plastic thing, exactly the sort of thing you'd want on an adventure or an investigation. It can actually be a flashlight [i]or[/i] a lantern, and it even has a little laser pointer attached, in case you want to point something out in the middle of a case. You've seen enough horror movies where something attacks from just outside the beam of the character's flashlight, so you've got it in lantern mode for tonight."
Before burning the lantern: try switching on the lantern instead.
A little laser pointer is part of the lantern. The description of the laser pointer is "For...pointing at ghosts, you suppose. Better to have it and not need it than to need it and not have it."
Instead of pushing or touching or switching on or waving or burning or rubbing the laser pointer:
	say "You shine the red beam around for a little bit.";
	if the tame ghost is in the location:
		say " There's a sudden flurry of air as the ghost chases the laser. You play with it for a minute, making it run around and around the room, until it gets tired and settles down next to you.";
		now the ghost is friendly.
Instead of putting the tarp on the tame ghost: say "You drop the tarp over the disturbance in the air, which dashes around, batting at it playfully. It rolls around and claws at the cloth for a few minutes until it gets tired and settles down next to you.";
	now the ghost is friendly.
Instead of putting the tarp on the wary ghost:
	move the tarp to the location;
	say "You try to aim at where you heard the sound, and launch the tarp at it with a wide, desperate throw. It tangles and wraps around [i]something[/i] in the air, which flails around wildly! You hold your breath, waiting to see what happens next. The tarp goes still...[p]And from under it you hear a quiet, definite 'mrow?'. The tarp unfolds as something invisible emerges from underneath it.";
	now the ghost is tame.
Before throwing the tarp at the ghost: try putting the tarp on the ghost instead. 
Before dropping the tarp in the presence of the ghost: say "(on the ground)[command clarification break]".
After switching on or switching off the lantern when the breaker panel is not switched on:
	say "You push the switch, and the lantern clicks [if the lantern is switched on]on[else]off[end if].";
	try looking.

The description of the notebook is "A thin, spiral-bound notebook, the sort of thing that's perfect for taking notes in during an investigation, or an adventure. You've already sketched in a map and a plan, amid the pages of old geometry notes.[p][i][bracket]You can examine the map and plan separately; they'll be updated automatically as you explore.[close bracket][/i]".
Some pages of old geometry notes are part of the notebook. The description is "Not relevant to the haunting. Hopefully."
Understand "journal" or "note" or "book" or "thin" as the notebook.

Part Map

A map is part of the notebook. The description is "[first time]As part of your preparations, you've spent a while surveying the manor from the outside, noting down its dimensions and where the rooms should be. The result is as detailed as you could make it without going in.[p]...which is not very detailed, to be honest.[p]It's a square. You've drawn a square. But now that you're in, you can update it as you go.[p][tut]If you're using a screen reader, the map below will sound like nonsense. Use READ TEXT MAP instead for a verbal description.[/tut][only][draw map][p][map legend]".
To say draw map:
	say fixed letter spacing;
	say "[maproom kitchen]-[maphoriz door1]-[maproom huge room]-[maphoriz jam1]-[maproom sunroom][br][mapvert door6]       [mapvert door2][br][maproom dining room]   [maproof]   [maproom library][br][mapvert jam2]       [mapvert door3][br][maproom sitting room]-[maphoriz door5]-[maproom entrance]-[maphoriz door4]-[maproom study]"; [This is going to be a pain in the ass to debug…]
	say variable letter spacing.
To say maproom (place - a room):
	if the place is the location:
		say "&";
	else if the place is not visited:
		say "+";
	else if the place is hauntable:
		if the place is the location of the ghost, say "G";
		otherwise say "@";
	else:
		say "o".
To say maphoriz (place - an internal-door):
	if the place is unseen:
		say "-";
	else if the place is jammed:
		say "#";
	else if the place is open:
		say "-";
	else:
		say "x".
To say mapvert (place - an internal-door):
	if the place is unseen:
		say "|";
	else if the place is jammed:
		say "#";
	else if the place is open:
		say "|";
	else:
		say "x".
To say maproof:
	if the location is the Roof, say "&";
	else say " ".
To say map legend:
	say "KEY: [if there is an unvisited room in the mansion-region]+ = unseen room, o = seen room, [end if][if there is a hauntable room]@ = detector, [end if]& = you[if the location of the ghost is hauntable], G = ghost[end if], x = closed door[if there is a seen jammed door], # = blocked door[end if]".
The mansion-region is a region. The kitchen, the huge room, the sunroom, the dining room, the library, the sitting room, the entrance, and the study are in the mansion-region.
[Every turn: say "Hauntable: [the list of hauntable rooms]."]

Part Tasks

A task is a kind of object. A task can be hidden, revealed, or complete (this is its status). A task is usually hidden. A task has some text called the description.
Correspondence relates one task (called the corresponding task) to one scene. The verb to correspond to means the reversed correspondence relation.
Definition: a scene is tasked if it corresponds to a task.
When a tasked scene (called the event) begins:
	if the event is not confinescene and the event is not befriendscene:
		if the corresponding task of the event is complete:
			say "You [if the notebook is not visible]mentally [end if]un-cross a step from your plan: '[description of the corresponding task of the event]'.";
		otherwise if the turn count is greater than one:
			say "You [if the notebook is not visible]mentally [end if]add another step to your plan: '[description of the corresponding task of the event]'.";
	now the corresponding task of the event is revealed;
	now the score is the number of complete tasks.
When a tasked scene (called the event) ends:
	if the event is not confinescene and the event is not befriendscene:
		say "And that step ('[description of the corresponding task of the event]') is complete. You [if the notebook is not visible]mentally [end if]check it off your list.";
	now the corresponding task of the event is complete;
	now the score is the number of complete tasks.

A tasklist is part of the notebook. Understand "task" or "list" or "tasks" or "plan" or "plans" as the tasklist.
The description of the tasklist is "You've sketched out a basic plan:[br][list tasks].".
To say list tasks:
	repeat with the item running through tasks:
		if the item is not hidden:
			say "    [description of the item]";
			if the item is complete:
				say " - DONE";
			say line break;
	let X be the number of complete tasks;
	let Y be the number of tasks that are not hidden;
	say "So far you've completed [X] of the [Y] steps".

The maximum score is 7.
Last report requesting the score: say "(If you read the plan in the notebook, it'll list which tasks are complete and which remain to be done.)".

Explorescene is a scene. It corresponds to exploretask. The description of exploretask is "Explore the mansion".
Explorescene begins when the Entire Game begins. Explorescene ends when all rooms in the mansion-region are visited.
Unjamscene is a scene. It corresponds to unjamtask. The description of unjamtask is "Unjam the doors".
Unjamscene begins when a jammed door is seen. Unjamscene ends when there are no jammed doors.
Evidencescene is a scene. It corresponds to evidencetask. The description of evidencetask is "Find evidence of the ghost".
Evidencescene begins when the Entire Game begins. Evidencescene ends when the ghost is noticed.
When evidencescene ends: say "There! That's definitely something unusual! There [i]is[/i] something in here other than you, something you can't see...".
Trapscene is a scene. It corresponds to traptask. The description of traptask is "Create a [i]ghost detector[/i]: something that will make noise if the ghost messes with it".
Trapscene begins when the Entire Game begins. Trapscene ends when a room is hauntable.
Locatescene is a scene. It corresponds to locatetask. The description of locatetask is "Set up ghost detectors and use them to track the ghost".
Locatescene begins when trapscene ends. Locatescene ends when the location of the ghost is hauntable.
Confinescene is a scene. It corresponds to confinetask. The description of confinetask is "Confine the ghost somehow[if there are no ghost-viable doors] (in a container)[end if]".
Confinescene begins when locatescene ends. Confinescene ends when the ghost is tame.
Befriendscene is a scene. It corresponds to befriendtask. The description of befriendtask is "Ghost cat??".
Befriendscene begins when confinescene ends. Befriendscene ends when the ghost is friendly.

When play begins:
	say "Everyone's heard stories about the old mansion on the hill. Decades ago, they say, old Doctor Black lived up there all alone. Until something happened[--]nobody knows what[--]and he vanished without a trace. The house belongs to the Historical Society now, it's turned into a little sort of local museum. But the south wing has always been closed to the public, and they say that's where it happened. Where he was murdered.[p]You don't really [i]believe[/i] in the ghost stories any more, of course. You're too old for that. He probably just had a heart attack. But it [i]is[/i] Halloween coming up, and Abby started telling the story, and you'd read that book and you told her it sounded like a [i]poltergeist[/i], a ghost that throws things around. Which means it has to be real and physical, right? Something you could find and trap.[p]And then Dylan made it a [i]dare[/i] and nobody wanted to back down. And that's how you ended up here, in the dead of night on Halloween, prying one of the boards off the window next to the door and squirming your way in.[p]None of the others showed up. But you are [i]not[/i] afraid of ghost stories, and you are [i]not[/i] going to chicken out like your friends did. One way or another, you're determined to find out the truth, just like the detectives in the books always do.[p]Welcome to..."

Volume IV - Miscellaneous

[This is where everything else got thrown as I did last-minute bug fixes before the deadline]

Some dust is a singular-named backdrop. It is in the kitchen, the huge room, the sunroom, the dining room, the library, the sitting room, the entrance, and the study. The description is "It's everywhere in here."
Some covered furniture is a lightbound singular-named backdrop. It is in the kitchen, the huge room, the sunroom, the dining room, the library, the sitting room, the entrance, and the study. The description is "Covered with sheets for who knows how long."
Some dim shapes are a darkbound backdrop. They are in the kitchen, the huge room, the sunroom, the dining room, the library, the sitting room, the entrance, and the study. The description is "They look horrifying in the darkness."
[Why can I not just use a region for this? I think it's a bug]

The description of yourself is "Dusty and a bit scraped up, but full of determination."

Singing is an action applying to nothing.
Understand "sing" or "shout" or "scream" or "panic" or "yell" as singing.
Instead of singing: say "You make some noise. It does nothing to make the house feel less vast and empty."
Understand the command "scooch" as "push".
Understand "hang [something preferably held] on/from [something]" as putting it on.
Specifically singing is an action applying to one topic. Understand "sing [text]" as specifically singing.
Before specifically singing: try singing instead.

Some moonlight is a backdrop. It is everywhere. The description is "A full moon is probably a good omen, right?" Understand "moon" or "light" as the moonlight.

[Rewritten tutorial that emphasizes the notebook and lantern]
To give the current tutorial:
	if initial tutorial is true:
		say "[tut]Type commands for your character to carry out in the game world. For example, you can LOOK to look around and get a description of your surroundings.[/tut]";
	otherwise if we have not examined and there is another portable thing (called the item) in the location:
		let T1 be "[the item]" in upper case;
		let T2 be "[item]" in upper case;
		say "[tut]Use the EXAMINE command to take a closer look at something. For example, EXAMINE [T1] (or just X [T2] for short).[/tut]";
	otherwise if we have not examined:
		say "[tut]Use the EXAMINE command to take a closer look at something. For example, EXAMINE ME (or just X ME for short).[/tut]";
	otherwise if we have not taken and there is another portable thing (called the item) in the location:
		let T be "[the item]" in upper case;
		say "[tut]Many puzzles in interactive fiction involve manipulating the objects around you. Try to TAKE [T].[/tut]";
	otherwise if there is an unhandled personal thing (called the item):
		say "[tut][The item] looks important. Better take that too.[/tut]";
	otherwise if we have not taken inventory and something is carried:
		say "[tut]To see what you're currently carrying, type INVENTORY (or I for short).[/tut]";
	otherwise if we have not examined the lantern:
		say "[tut]The lantern seems important. Why not EXAMINE it for clues as well?[/tut]";
	otherwise if we have not switched on the lantern:
		say "[tut]From the description, it sounds like the lantern can be manipulated. Maybe we can turn it on and get some more light to see by.[/tut]";
	otherwise if we have not examined the notebook:
		say "[tut]The notebook seems important. Why not EXAMINE it for clues as well?[/tut]";
	otherwise if we have not gone and there is a tut-viable direction (called the way):
		let T be "[way]" in upper case;
		say "[tut]You can navigate around the map with compass directions, like GO [T] (or just [T]).[/tut]";
	otherwise:
		say "[tut]You've got the hang of this now! If you get stuck, remember to EXAMINE anything that stands out, and see what you can do with those things: take and drop them, open and close them, push and pull them, climb them, put things inside them, and so on. If something goes horribly wrong, you can always UNDO and try something else.[/tut]";
		now tutorial mode is false.

Volume V - Post-Comp Fixes

Understand the command "grab" as "take".

Instead of taking the shattered china: say "The pieces are so small they wouldn't be useful for anything."

Instead of doing anything when the noun is the ghost or the second noun is the ghost:
	if the ghost is friendly:
		say "The ghost darts around playfully.";
	otherwise:
		say "You think the ghost is in here somewhere, but you certainly can't see it. You'll have to approach it a bit less directly, or maybe confine it more somehow."

Before going down when the player is on the ladder: try exiting instead. [The Standard Rules have code to redirect "out" but not "down" like this.]

The player is lit. [This means you'll never be in "true" darkness, because I'm not using Inform's lighting system. Testers discovered that you could shut yourself in the wardrobe and suddenly the lantern wouldn't work.]

[There's some oddness with "put books on shelves" when the armload isn't carried: the game tries implicitly taking the pile, then says it fails because the pile isn't carried (the armload is). This works around that oddity.]
Before putting the heap of books on something:
	if the armload of books is not carried:
		try taking the heap of books; [Not using implicit taking here because we don't want to check if the pile is carried]
	try putting the armload of books on the second noun instead.

Understand the command "point" as "wave".
Waving it at is an action applying to one thing and one visible thing. Understand "wave [something preferably held] at [something]" as waving it at.
Before waving something at: try waving the noun instead. [Second noun doesn't matter here]

Understand "stack [something]" as rubbing. ["Cleaning" would be a better name for this action: STACK BOOKS]
Instead of rubbing the heap of books: say "You start making a stack of books on the floor, but it topples over as soon as you get to the fourth one."
Understand "stack [something] on/onto [something]" as putting it on. [STACK BOOKS ON SHELVES]

Part Missing Descriptions

[Definition: a thing is descriptionless if the description of it is empty.
When play begins:
	say "Undescribed: [the list of descriptionless things]."]
[At this point, the only descriptionless things should be no-key (doesn't actually exist), the top of the desk, and the desk drawers (examining them is redirected to other actions).]
The description of the shattered china is "Someone has smashed it to slivers."
The description of the breaker panel is "A gray metal box with a big lever sticking out of it. It seems like it should have a label that says what the lever [i]does[/i], but no luck."
The description of the counters is "Cold and hard and probably made out of something fancy, but you're not sure what."
The description of the little hook is "Firmly affixed to the ceiling, for supporting...hanging plant pots, maybe? Something like that."
The description of the toppled furniture is "A couple of the stacks have fallen like dominoes, leaving furniture scattered everywhere and making the whole room a hazard to your shins and elbows[if uncleared]. One table has fallen against the east door, jamming it shut[else]. You've managed to drag the table away from the east door, at least[end if].". Understand "chairs" or "tables" or "chair" or "table" as the toppled furniture.
The description of the shelves is "Given how much they're sagging, they must have been filled with hundreds and hundreds of books, at one point."
Before examining the top of the desk: try searching the noun instead.
Before examining the desk drawers: try searching the noun instead.
The description of the tiny silver key is "It's less than an inch long, and still shiny, which probably means it's not actual silver. Silver gets tarnished if it sits around for too long, doesn't it? That sounds right."
The description of the big table is "You can imagine the old doctor sitting all his guests around this table for a fancy dinner, not knowing it was going to be the last night of his life on this earth. Or...wait, was he alone in the mansion when he died? If he was murdered there must have been some guests."
The description of the mess of fallen boxes is "This room has been turned into some kind of storage space for all these boxes, and you have to climb over them to get from one side to the other[if uncleared]. A couple of them are blocking the door to the south[else]. At least the door to the south is clear now[end if]."
The description of the main door is "On the outside it's all very grand and imposing, but from in here it looks the same as all the other doors."
The description of an internal-door is usually "It's currently [if open]open[else]closed[end if]."
The description of the curtain rod is "There must have been heavy curtains over the windows at some point, but someone has slashed them to shreds[--]letting you see just how securely the windows were boarded up from the other side. There's no escape that way."
The description of the ghost is "You squint and peer at it out of the corner of your eye, but still can't make anything out." [This shouldn't be printed, because there's other code for interacting with the ghost, but better safe than sorry. "You see nothing special about the ghost" is a bit silly.]

Part Text Map

Include Enhanced Route Finding 6M62 by Daniel Stelzer. [Needed to determine which rooms the ghost can access]

A textmap is part of the notebook. Understand "text map" or "text" or "accessible" or "accessible map"  as the textmap. The description of the textmap is "[accessible map].".
Definition: a room is frontier if it is visited and it is near an unvisited room in the mansion-region.
Definition: a room is jammed-adjacent if a seen jammed internal-door is liminal to it.
Definition: a room is ghost-reachable rather than ghost-unreachable if it is the location of the ghost or the best route from it to the location of the ghost using open unjammed doors is not nothing.
Definition: a room is unhauntable if it is not hauntable.
To say accessible map:
	let N be the number of unvisited rooms in the mansion-region;
	if N is not zero, say "There [regarding N][are] [N in words] room[s] unexplored: try the doors from [the list of frontier rooms].[p]";
	let N be the number of seen jammed internal-doors;
	if N is not zero, say "You've seen [regarding N][N in words] jammed door[s]: you can reach [them] from [the list of visited jammed-adjacent rooms].[p]";
	if the location of the ghost is hauntable, say "From the sound, you know that the ghost is currently in [the location of the ghost].[p]";
	let jam-present be whether or not there is a jammed door;
	let unhaunt-present be whether or not there is an unhauntable room in the mansion-region;
	let haunt-present be whether or not there is a hauntable room in the mansion-region;
	let unreach-present be whether or not there is a ghost-unreachable room in the mansion-region;
	let unhaunt-reach-present be whether or not there is a ghost-reachable unhauntable room in the mansion-region;
	if haunt-present is false: [No ghost detectors]
		say "You haven't set up any ghost detectors yet, but they'll be listed here once you do";
	otherwise if unhaunt-present is false: [All ghost detectors]
		say "You've set up ghost detectors in every room[if unreach-present is true], and confined the ghost to [the list of ghost-reachable rooms in the mansion-region][end if]";
	otherwise if jam-present is true or unreach-present is false: [Ghost's movement not intentionally restricted]
		let N be the number of hauntable rooms in the mansion-region;
		say "You've set up [regarding N][N in words] ghost detector[s]. You're missing [the list of unhauntable rooms in the mansion-region]";
	otherwise: [Ghost's movement restricted, some but not all detectors]
		let N be the number of unhauntable ghost-reachable rooms;
		say "The ghost is restricted to [the list of ghost-reachable rooms][if unhaunt-reach-present is true]. Out of those, [the list of unhauntable ghost-reachable rooms] [regarding N][do]n't have a detector[end if]";