Scroll Thief — 104 of 138

Section B - Sound Solution

Instead of someone attacking the ducts:

take full time;

if the actor is the Adventurer, now the Adventurer success flag is true;

if the player can see the actor:

say "[The actor] [strike] the duct, which reverberates noisily. [r]";

otherwise:

say "A loud [i]crash[/i] of metal against metal reverberates through the Library. [r]";

if the player is in the Clean-Room:

say "The echoes slowly die away.";

otherwise if the player is in the Disused Closet:

say "The sound seems to be coming from a small vent near the floor.";

solve the vent;

otherwise:

let the front cut be the number of moves from the location to the Disused Closet, using even locked doors;

let the back cut be the number of moves from the location to the Clean-Room, using even locked doors;

if front cut is -1 and back cut is -1, say "[p]" instead;

let the way be nothing;

if the location is the top of the staircase:

let the way be southeast;

otherwise if the location is the Spell Research Room:

let the way be east;

otherwise if front cut is -1 or back cut is less than front cut and back cut is not -1:

let the way be the best route from the location to the Clean-Room, using even locked doors;

otherwise:

let the way be the best route from the location to the Disused Closet, using even locked doors;

if the way is nothing, say "[p]" instead; [This should never happen.]

say "You can hear the sound echoing faintly from [the way]."

Instead of an actor inserting a palantir into the small vent: [Only palantiri fit, don't worry about mirrors.]

if the Clean-Room encloses a palantir (called the ball), say "[The ball] [are] already down there; best not to send another yet.";

if the noun is the black sphere and hard mode is true, say "Unfortunately the black sphere seems to be slightly larger than the others, and it doesn't quite fit into the opening of the vent." instead;

take full time;

if the player can see the actor, say "[The actor] [slide] [the noun] into the vent, and it quickly rolls out of sight into the darkness. A moment later, there is an enormous [i]CLANG![/i] from somewhere below.";

move the noun to the oven;

if the actor is the player and the player can see the Adventurer:

say "[The Adventurer] jumps.".