Scroll Thief — 115 of 138

Book II - The Caves, Continued

Chapter 1 - Top Level

Section A - Geography and Climbing

There is a cave in Colossal Cave called Above the Pit. "The passage twists and narrows until eventually you can no longer move forward. Only a tiny crack continues on to the west, but a gap in the floor opens onto a larger cavern below you. A few traces of white mist rise from the pit, reflecting the light eerily."

Instead of going east in the Splendid Cavern: say "You might potentially fit through there, but your claustrophobia holds you back."

Instead of the Adventurer going east in the Splendid Cavern:

if the player can see the Adventurer, say "'There's nothing much that way. The entrance is closed at the moment, so you can't go out there.'";

take full time;

record the Adventurer's attempt as successful.

The Splendid Cavern is east of Above the Pit.

Effect of casting vezza at the Splendid Cavern: say "A [if the Adventurer is feminine]wo[end if]man edges carefully back through the crack to the east."

Inverse effect of casting vezza at the Splendid Cavern: say "A small bird flutters through the room, chirping quietly and looking very out of place."

Effect of casting vezza at the Splendid Cavern: say "The rope has come untied and is nowhere to be seen."

Inverse effect of casting vezza at the Splendid Cavern: say "The Adventurer hammers a hook into the wall, affixes a rope, and begins to climb down into the pit."

A small hook is fixed in place in Above the Pit. It is ropable. "A small hook has been driven into the rock above the pit." The description of the hook is "A rope tied here would make it significantly easier to climb down the pit, which is probably the reason for its presence."

An old rope is a rope in Above the Pit. "An old rope is tied to the hook, coiled at the edge of the pit." It is tied to the small hook. The description of the rope is "It's dusty and worn, but still seems quite strong."

Instead of going down from Above the Pit:

if the player is flying:

say "You step off the ledge and float gently down...";

continue the action;

if the dome is traversable:

say "You climb carefully down the rope...";

continue the action;

say "You don't have a good way down.".

Instead of going up from the Misty Cavern:

if the player is flying:

say "You jump with all your strength, and float back up...";

continue the action;

if the dome is traversable:

say "With a bit of difficulty, you pull yourself back up the rope...";

continue the action;

repeat with the item running through things in Above the Pit:

if the player can touch something which is tied to the item:

say "The rope isn't anchored well enough to hold your weight.";

stop the action;

say "You don't have any good way to climb up.".

After the Adventurer going up from the Misty Cavern:

if the player can see the Misty Cavern, say "[The Adventurer] climbs quickly to the top of the pit, digging [her] hands into tiny cracks in the rock." instead;

if the player can see Above the Pit, say "[The Adventurer] appears at the top of the pit, climbing without any apparent effort." instead;

continue the action.

After the Adventurer going down from Above the Pit:

if the player can see Above the Pit, say "[The Adventurer] grabs onto the apparently sheer rock, climbing down easily." instead;

if the player can see Above the Pit, say "[The Adventurer] slithers down from the top of the pit." instead;

continue the action.

Instead of an actor climbing a rope when the noun is in Above the Pit or the noun is in the Misty Cavern: [Redirect CLIMB ROPE to a going action.]

if the dome is traversable:

if the location of the actor is the Misty Cavern, try going up;

otherwise try going down;

otherwise:

try pulling the noun.

To decide whether the dome is traversable:

repeat with the anchor running through tied up anchored things in Above the Pit:

let the coil be a random rope which is tied to the anchor;

if the player encloses the coil:

initialize the implicit action; [Implicit Action framework for nicer reporting.]

silently try dropping the coil;

finish the implicit action with participle "dropping" infinitive "drop" object "[the coil]" and condition (whether or not the player does not carry the coil);

if the coil is enclosed by a person, no;

repeat with the target running through things which are tied to the anchor:

if the location of the target is the Misty Cavern:

yes;

if the location is Above the Pit:

let the item be a random rope which is tied to the anchor;

repeat with the target running through things tied to the item:

if the target is not the item and the target is not the anchor, now the item is the target;

initialize the implicit action; [Implicit Action framework for nicer reporting.]

silently try throwing the item at down;

finish the implicit action with participle "throwing" infinitive "throw" object "[the item] into the pit" and condition (whether or not the item is in the Misty Cavern);

if the location of the item is the Misty Cavern, yes;

no.