Scroll Thief — 62 of 138

Chapter 5 - Effects of Spells

Section A - Enchanter

[Gnusto]

Instead of casting gnusto at the player:

say "The [i]gnusto[/i] spell is not designed to copy spells out from memory[--]it needs a physical copy of the scroll."

Effect of casting gnusto at something that is not a spell scroll when the second noun is not a spell book:

say "The [i]gnusto[/i] spell finds no incantation to copy, and fades away."

Effect of casting gnusto at a blank spell scroll:

say "The [i]gnusto[/i] spell attempts to copy [the second noun] into your spellbook, but finds no incantation written on it."

Effect of casting gnusto at a spell book:

say "The spell fizzles. Unlike spell scrolls, spell books are magically guarded against the [']theft['] of their lore.";

say "[note][bracket]If you want to prepare a spell from a spell book in order to cast it later, try PREPARE [a random spell inscribed in the second noun in capitals].[close bracket][/note][br]".

Instead of casting gnusto at your spell book when the player is not reversed:

say "The [i]gnusto[/i] spell doesn't work that way: you cast it at a spell on a scroll, and it copies it into your spellbook."

Should the game suggest casting gnusto at something that is not a spell scroll when testing the second noun: it is a bad suggestion.

Effect of casting gnusto at a spell scroll when the player does not carry the player's preferred spell book (this is the search for spell book rule):

if the player can touch the player's preferred spell book:

carry out the implicitly taking activity with the player's preferred spell book;

if the player carries the player's preferred spell book, abide by the standard gnusto rule;

say "The spell quests around in your hands, looking for [the player's preferred spell book], and, not finding it, fades reluctantly."

Effect of casting gnusto at a spell scroll (this is the standard gnusto rule):

let xyzzy be the inscribed spell of the second noun;

let the tome be the player's preferred spell book; [Shorter to type.]

say "[The tome] begins to glow softly. [if xyzzy is inscribed in the tome]A wisp of light traces over the [i][xyzzy][/i] spell in glowing letters, the old words beginning to shine[else]Slowly, ornately, the words of the [i][xyzzy][/i] spell are inscribed, glowing[end if] even more brightly than the book itself. The book's brightness fades, but the spell remains! However, [the second noun] on which it was written [vanish] as the last word is copied[if xyzzy is inscribed in the tome].[p]Perhaps you'll know it especially well now[end if].";

add xyzzy to the tome;

now the remembered location of the second noun is nothing;

remove the second noun from play.

Effect of casting gnusto at a powerful spell scroll: [This catches semipowerful scrolls as well.]

let the tome be the player's preferred spell book;

if the player does not carry the tome, let the tome be a random spell book carried by the player;

say "[The tome] begins to glow softly. In a spectacular effort of magic, the powers of the [i]gnusto[/i] spell attempt to copy the [inscribed spell of the second noun] spell into your book, but the spell is too long, too complicated, and too powerful. The glow fades, but fortunately [the second noun] remains intact.";

rule succeeds.

Empowered effect of casting gnusto at a somewhat powerful spell scroll: [YONKed GNUSTO is more powerful than normal GNUSTO.]

if the player does not carry the player's preferred spell book, abide by the search for spell book rule;

otherwise abide by the standard gnusto rule.

Empowered effect of casting gnusto at an overpowered spell scroll: [Still not enough!]

let the tome be the player's preferred spell book;

if the player does not carry the tome, let the tome be a random spell book carried by the player;

say "[The tome] begins to glow softly. In an amazingly spectacular effort of magic, the powers of the enhanced [i]gnusto[/i] spell attempt to copy [inscribed spell of the second noun] into your book, but even with the aid of [i]yonk[/i] this spell is just barely too powerful. The glow fades, but fortunately [the second noun] remains intact.";

rule succeeds.

Inverse effect of casting gnusto at a spell scroll:

say "The [i]gnusto[/i] spell does something to the scroll, but you see no obvious effect. Perhaps reverse-[i]gnusto[/i] is meant to be used on a spell book?".

Inverse effect of casting gnusto at a spell book:

say "The [i]gnusto[/i] spell does something to the book, but you see no obvious effect. Thankfully, it didn't remove any spells from it."

Should the game suggest casting gnusto at a spell scroll when testing the second noun: it is a good suggestion.

[As per Jacq's request, an easter egg...]

The gusto flag is initially false.

After reading a command:

if the player's command includes "with gusto":

now the gusto flag is true;

cut the matched text;

otherwise:

now the gusto flag is false.

Before doing anything when the gusto flag is true:

say "You put as much effort as you can muster into [the current action].";

now the gusto flag is false. [In case of multi-part commands--this isn't perfect in the case of GO NORTH THEN GO SOUTH WITH GUSTO but prevents the message from repeating too much.]

[Frotz]

Instead of casting frotz at a lit thing when the player is not reversed:

say "Why bother? [regarding the second noun][They're] glowing already."

Instead of casting frotz at an unlit thing when the player is reversed:

say "Why bother? [regarding the second noun][They're] not glowing in the first place."

Instead of casting frotz at a distant lit thing when the player is reversed: [LLEPS FROTZ SUN, LLEPS FROTZ STARS, etc.]

say "Indulge in such an act of hubris? Never. Humility is an important virtue for an Enchanter."

Effect of casting frotz at a room:

say "A soft yellow glow permeates the area.";

now the second noun is lit;

[ affect the second noun with frotz for 20 turns with final effect unfrotzing. ]

Inverse effect of casting frotz at a room:

say "The light in the area grows dimmer.";

now the second noun is unlit;

[ remove further effects of frotz from the noun. ]

Effect of casting frotz at an active scrying device:

let the far glass be the mystical relative of the second noun;

if the player can see the far glass:

say "With twin bursts of light, [the second noun] and [the far glass] both begin to glow!";

otherwise:

say "[The second noun] [begin] to glow with a faint and somewhat distorted light.";

now the second noun is lit;

now the second noun is affected by frotz;

now the far glass is lit;

now the far glass is affected by frotz.

Effect of casting frotz at something:

say "There is an almost blinding flash of light as [the second noun] [begin] to glow! It slowly fades to a less painful level, but [if the second noun is a person][they] [are] now shining quite brightly[else][the second noun] [are] now quite usable as a light source[end if].";

now the second noun is lit;

now the second noun is affected by frotz.

Empowered effect of casting frotz at something:

say "There is an incredibly bright flash of light as [the second noun] [begin] to glow! It quickly fades to a less painful level, but [if the second noun is a person][they] [are] now shining very brightly[else][the second noun] [are] now definitely usable as a light source[end if].";

now the second noun is lit;

now the second noun is affected by frotz.

Effect of casting frotz at the player:

say "There is an almost blinding flash of light. You are bathed in a shimmering golden glow, bright enough to read by.";

now the player is lit;

now the player is affected by frotz.

Empowered effect of casting frotz at the player:

say "There is a brilliantly bright flash of light. You are now bathed in a bright golden glow.";

now the player is lit;

now the player is affected by frotz.

Inverse effect of casting frotz at something:

say "A pool of darkness covers [the second noun], then retreats. [They] [are] no longer glowing.";

now the second noun is unlit;

now the second noun is not affected by frotz;

if the second noun is an active scrying device:

let the far glass be the mystical relative of the second noun;

if the player can see the far glass, say "[The far glass] also [cease] to glow.";

now the far glass is unlit;

now the far glass is not affected by frotz.

Inverse effect of casting frotz at the player:

say "Darkness sweeps over you, and you are no longer glowing.";

now the player is unlit;

now the player is not affected by frotz.

Reset for frotz:

if the player can see the currently reset object, say "The [i]frotz[/i] spell on [if the the currently reset object is the player][regarding the player]your body[else][the currently reset object][end if] wears off, and [their] magical glow fades.";

now the currently reset object is unlit;

Reset for frotz when the currently reset object is an active scrying device:

now the mystical relative of the currently reset object is unlit;

make no decision.

[Blorb]

The strongbox is a fixed in place container. It is closed, locked, openable, ropable, [lit,] and visible between rooms. Understand "magical" or "strong" or "box" or "glowing" as the strongbox. The printed name of the strongbox is "magical strongbox". The description of the strongbox is "Now that the spell has been cast, it looks like nothing more than an ordinary metal safe[first time]. You wonder briefly whether it could really be unlocked with a key[--]but no, there is no keyhole[only]."

Instead of an actor attacking the strongbox: if the player can see the actor, say "[The actor] [thwack] the box, but it serves its purpose well and does not give."; take full time.

Instead of taking the strongbox: say "You attempt to lift it, but it's far too heavy."; take full time.

Effect of casting blorb at something when the second noun is fixed in place or the second noun is scenery:

say "A glowing outline appears in midair, growing to encompass [the second noun]. It spreads farther and farther in an attempt to isolate [them] from [their] surroundings, but eventually gives up and fades away without effect."

Effect of casting blorb at something when the second noun is part of something or the second noun is worn by something:

say "The spell attempts to surround [the second noun], but [you or the holder of the second noun] [are] in the way, and it dissipates without effect."

Effect of casting blorb at something (this is the standard blorb rule):

if the player can see the strongbox, say "The previous strongbox disintegrates into mist as your magic is focused on [the second noun].";

if the strongbox is on-stage: [Reset a previous blorb casting.]

let the home be the holder of the strongbox;

repeat with the item running through things in the strongbox:

move the item to the home;

now the strongbox is not tied to anything;

say "A glowing strongbox forms out of the air, carefully enclosing [the second noun], which disappears from view. [r]";

let the holder be the holder of the second noun;

if the holder is a room, say "The strongbox rests on the ground. [r]";

if the holder is a container, say "The box [if the box is closed]settles in[else]falls into[end if] [the holder]. [r]";

if the holder is a supporter, say "The box falls onto [the holder]. [r]";

move the strongbox to the holder;

while the holder of the strongbox is not a room and the holder of the strongbox is portable:

if the holder of the strongbox is a person, say "[The holder of the strongbox] [struggle] with the weight, and it slips from [their] grasp. [r]";

otherwise say "[The holder of the strongbox] [are] too small to hold it, and it falls out. [r]";

move the strongbox to the holder of the holder of the strongbox;

move the second noun to the strongbox;

if the second noun is tied up:

if the second noun is a rope:

say "[The list of nonrope things tied to the second noun] [are] suddenly freed as [the second noun] [are] pulled away. [r]";

otherwise:

now the second noun is tied to the strongbox; [This links the strongbox to the rope and everything else.]

say "[The random rope which is tied to the strongbox] [are] pushed aside, and [adapt the verb end] up wrapped tightly around the strongbox. [r]"; [The circumlocution here is because [end] prints the name of the Dead End room.]

now the second noun is not tied to anything;

say "It appears solid and secure, but you get the feeling that it would open at your slightest touch.";

set pronouns from the strongbox;

now the remembered location of the second noun is the strongbox;

unless the second noun is a person, now the second noun is handled.

Effect of casting blorb at the player:

say "You experience the most peculiar sensation of being simultaneously shrunken and sucked into what might best be likened to a black hole. The effect is not without its exhilarating aspect; as a way of life, however, it leaves much to be desired.";

record "Blorbed out of existence" as an ending;

end the story saying "You have left this plane of existence".

Instead of casting blorb at the strongbox when the player is not reversed:

say "Who knows what sort of magical catastrophe could result from that sort of recursion?".

To empty the strongbox:

repeat with the item running through things in the strongbox:

move the item to the holder of the strongbox;

if the item is a person and the player can see the strongbox, say "[The item] [seem] strangely unperturbed for having just been trapped in a magical strongbox.";

now the strongbox is not tied to anything;

remove the strongbox from play.

Instead of touching or opening or unbolting the strongbox:

take full time;

say "As you open the strongbox it vanishes, and [the list of things in the strongbox] appear[if the number of things in the strongbox is less than two]s[end if] in its place.";

empty the strongbox.

Instead of unlocking the strongbox with something:

say "[The second noun] is unnecessary[--]your touch is enough.";

try touching the strongbox.

Inverse effect of casting blorb at something:

say "You cast the spell, but nothing obvious happens to [the second noun]. Perhaps anti-[i]blorb[/i] only works on strongboxes?".

Inverse effect of casting blorb at the strongbox:

say "The strongbox melts away, and [the list of things in the strongbox] appear[if the number of things in the strongbox is less than two]s[end if] in its place.";

empty the strongbox.

Effect of casting kulcad at the strongbox:

say "The strongbox rips and tears as though made of paper. The shreds scatter and disappear.";

remove the strongbox from play. [Notably, things in the box do NOT come back.]

[Nitfol]

Effect of casting nitfol at the player:

say "For a moment you feel a slight echo in your thoughts, as though each word you say is being reinterpreted and repeated in your mind."

Effect of casting nitfol at something:

say "[The second noun] isn't very talkative."

Effect of casting nitfol at an animal:

say "You feel somewhat more attuned to [the second noun] as the spell completes.";

affect the second noun with nitfol for 10 turns.

Instead of conversing when the noun is an animal and the noun is not affected by nitfol (this is the can't talk to animals without magic rule):

say "It doesn't seem like [the noun] can understand you.".

Instead of saying hello to or saying goodbye to an animal when the noun is not affected by nitfol and the greeting type is explicit (this is the can't greet animals without magic rule):

say "[The noun] [seem] to take no notice."

Persuasion for asking an animal (called the subject) to try doing something when the subject is not affected by nitfol (this is the can't persuade animals without magic rule):

say "[The subject] [do]n't seem to understand the instruction.";

persuasion fails.

Persuasion for asking an animal to try doing something: [Better response than 'the person has better things to do'.]

say "[The person asked] [take] no notice.";

persuasion fails.

[Rezrov]

Should the game suggest casting rezrov at something that is not openable when testing the second noun: it is a bad suggestion.

Should the game suggest casting rezrov at something that is open when testing the second noun: it is a bad suggestion.

[Should the game suggest casting rezrov at something that is locked: it is a good suggestion.]

Effect of casting rezrov at something nonrope that is not openable:

say "Nothing happens. It seems opening [the second noun] is beyond the power of the [i]rezrov[/i] spell."

Instead of casting rezrov at a person:

say "Surgeons might find that helpful if it worked, but it doesn't."

Instead of casting rezrov at something open when the player is not reversed:

say "Why bother? [regarding the second noun][They're] open already."

Effect of casting rezrov at something locked:

say "[The second noun] [click] open.";

now the second noun is unlocked;

now the second noun is open.

Effect of casting rezrov at a rope:

say "[The second noun] [twist] and [stiffen], [if the second noun is tied up]undoing [their] knots and [end if]falling into a pile on the floor.";

repeat with the item running through things tied to the second noun:

if the location of the item is the location, move the second noun to the holder of the item; [Make it come toward the player if possible.]

now the item is not tied to anything.

Effect of casting rezrov at something unlocked that is nonrope:

say "[The second noun] [open] at the first touch of magic[first time]. Half disappointing and half satisfying, like swatting a fly with a sledge hammer[only].";

now the second noun is open.

Inverse effect of casting rezrov at something openable:

if the second noun is open:

say "[The second noun] [slam] shut";

otherwise:

say "[The second noun] [shudder]";

if the second noun is unlocked:

say " and [lock]";

say ".";

now the second noun is closed;

now the second noun is locked.

Instead of casting rezrov at a person when the player is reversed:

say "Thankfully, that isn't necessary."

Effect of casting rezrov at the strongbox:

say "The strongbox melts away, and [the list of things in the strongbox] [appear] in its place.";

empty the strongbox.

[Gondar]

Effect of casting gondar at something:

say "The [i]gondar[/i] spell finds no way to extinguish [the second noun]."

Inverse effect of casting gondar at something:

say "[The second noun] bursts into spectral flame for a few moments, but appears to be unharmed."

[Krebf]

A thing can be undamaged or damaged. A thing is usually undamaged.

Effect of casting krebf at something:

say "The [i]krebf[/i] spell finds no way to repair [the second noun]."

Effect of casting krebf at a damaged thing:

say "[The second noun] [shine] faintly for a moment, [their] material flowing and distorting with a strange backward roar. When it finishes, no signs of vandalism remain.";

now the second noun is undamaged.

Inverse effect of casting krebf at something:

say "The reverse-[i]krebf[/i] spell doesn't seem to have any effect[one of]. Vandalism will have to proceed through more mundane methods[or]. At any rate, it doesn't cause willful damage[or][stopping]."

[Zifmia]

A person has a list of objects called the summoning stack.

To push (destination - an object) to/on/onto/into the/-- summoning stack of (subject - a person):

add the destination to the summoning stack of the subject.

To decide what object is the/an/-- entry pulled from the/-- summoning stack of (subject - a person):

let N be the number of entries in the summoning stack of the subject;

if N is zero, decide on nothing;

let the destination be entry N of the summoning stack of the subject;

remove entry N from the summoning stack of the subject;

decide on the destination.

The casting it at action has an object called the unsummoning destination.

Effect of casting zifmia at the player:

say "There is a flash of light and you find yourself standing a few feet from your former location. Amazing!"

Effect of casting zifmia at a person when the location of the noun is the location:

say "Nothing happens, perhaps because [the noun] [are] too close. The spell probably has a minimum range or something like that."

Effect of casting zifmia at a person when the second noun is affected by vardik:

say "Something feels wrong about the casting, and [the second noun] [fail] to appear."

Effect of casting zifmia at a person:

say "In a flash of light, [the second noun] suddenly [appear] before you.";

move the second noun to the location.

First effect of casting zifmia at a person (this is the check summoning to forbidden locations rule):

if the location is blorple-forbidden or the location of the second noun is blorple-forbidden, say "You begin the spell but something feels wrong about it, and it dissipates without any real effect.";

otherwise continue the action.

First effect of casting zifmia at a person (this is the zifmia setup rule): [This one's actually listed first.]

push the holder of the second noun onto the summoning stack of the second noun;

now the second noun is not tied to anything;

make no decision.

First inverse effect of casting zifmia at a person (this is the check unsummoning to forbidden location rule):

let the place be the unsummoning destination;

if the place is not a room, now the place is the location of the place;

if the location of the second noun is blorple-forbidden or the place is blorple-forbidden, say "Something doesn't feel quite right as you begin the spell, and it dissipates without any obvious effect.";

otherwise continue the action.

First inverse effect of casting zifmia at a person (this is the reverse zifmia setup rule): [Again, this one is actually first.]

if the location of the second noun is the Clean-Room: [The Clean Room's magic makes it easier.]

say "You feel an additional burst of power as the residual magic of the Clean Room assists you[first time]. It seems banishing summoned creatures is an important concern [if the location is not the Clean-Room]t[end if]here[only].";

now the unsummoning destination is entry 1 of the summoning stack of the second noun; [Take the entry from the bottom.]

truncate the summoning stack of the second noun to zero entries; [Then empty the stack.]

otherwise:

now the unsummoning destination is an entry pulled from the summoning stack of the second noun;

make no decision.

Inverse effect of casting zifmia at a person:

if the unsummoning destination is nothing, make no decision;

if the second noun is the player:

say "Space twists strangely for a moment...";

award the "Word of Recall" achievement;

otherwise:

say "[The second noun] [seem] to waver for a moment, then [disappear] with a slight [i]pop[/i].";

if the player can see the unsummoning destination, say "[They] [appear] again [if the unsummoning destination is a supporter]o[else]i[end if]n [the unsummoning destination].";

now the second noun is not tied to anything;

move the second noun to the unsummoning destination;

if the current interlocutor is the second noun, reset the interlocutor.

Understand "zifmia" as "[zifmia]".

Vaguely summoning is an action applying to one topic. Understand "[zifmia] [text]" or "cast [zifmia] at/on [text]" as vaguely summoning.

Should the game choose vaguely summoning: it is a good choice.

Check vaguely summoning (this is the can't vaguely summon without zifmia rule):

unless the player can cast zifmia at nothing, stop the action.

Carry out vaguely summoning:

increment the casting count of zifmia.

The report vaguely summoning rulebook has default success.

Report vaguely summoning: say "Nothing happens. Summoning of beings is very difficult unless the beings can be seen, and usually only works if the target has some great magic of their own."

Understand "a/the/-- jeearr/demon" or "the/-- unseen terror" as "[unseen terror]".

Report vaguely summoning "[unseen terror]":

say "The spell activates, and seems to have had an effect, but nothing obvious happens at first. Then you suddenly feel a strange chill in the air, and hear a laugh inside your head.

[i]Foolish student...[/i]

You are suddenly aware of a vague and wispy shape materializing in the air around you.

[i]...at last...[/i]

You try to run, but your whole body seems to be paralyzed. You can't even breathe.

[i]...I am released![/i]

The mist grows thicker and denser, compressing into a sort of cloud around you.

[i]Imprisoned for so long...[/i]

You try desperately to breathe, to blink, to move in some way. But your body refuses to obey you.

[i]...denied my power, denied even my form...[/i]

You can barely see now through the swirling cloud. It begins to glow with flickers of red and deep black.

[i]But now, another chance.[/i]

The echoing voice in your mind grows louder and louder, drowning out the sounds of the world.

[i]A new body, a new form, a new life.[/i]

The cloud suddenly pours forward, streaming into your eyes and mouth. A terrible coldness fills your body.

[i]Hm...'[/br][player's forename]'. [player's full name]. I like it. This is the name the people will fear.[/i]

There is a sharp pain behind your eyes, and images start flashing through your thoughts. Breaking into the library. Preparing your spell book. Sitting through exams. Casting your first spell. Coming to GUE Tech...scenes from your life, running backwards as far as you can remember.

[i]Indeed. This form will serve me nicely.[/i]

Suddenly the mist is gone. You hear the laughter again, but this time it is not in your mind. It is coming from your own mouth.

[alert]YES.

SO IT BEGINS.[/alert]

Your arm twitches, then waves in front of you. You are breathing again, very faintly. Your legs begin to move. You begin to walk, hesitantly, then faster as it familiarizes itself with your body.

You can do nothing but watch helplessly as you, as [i]it[/i], returns to the college. Following your memories from earlier it seeks out the dormitories, drawing traces of magic and memory from those it passes.

As its powers grow, the spirit grants you a vision of the future. You see the people of the land toiling to erect great idols to you. Parents offer up their own children upon these altars. The rivers of the land fill with blood. And [i]you[/i] embody this horror; [i]your[/i] name is cursed by every victim; [i]your[/i] face adorns the idols.

And worst of all, you remain awake and aware, a witness to everything, never sleeping, and never, ever to escape.";

now the score is -999;

record "Summoning a demon and taking over the world" as an ending;

end the story saying "You suffer an eternity of torment".

Report vaguely summoning "a/the/-- librarian/librarians":

say "You focus on your memories of the librarians, and you can feel your spell beginning to take shape...but then it collapses in on itself and fizzles out."

Understand "p/-- david/dave/-- lebling" or "marc/-- blank" or "steven/steve/-- meretzky" or "the/-- implementors/implementers" as "[implementors]".

Understand "tim/-- anderson" or "bob/robert/-- bates" or "michael/mike/-- berlyn" or "amy/-- briggs" or "bruce/-- daniels" or "stu/-- galley" or "brian/-- moriarty" as "[other implementors]".

Report vaguely summoning "[implementors]" for the first time:

say "Space warps for a moment, and the original Implementers of this world appear before you. After a few seconds of stunned silence, they speak:[br]

Steve Meretzky: 'What's going on here?'[br]

Marc Blank: 'I think it's the old [i]zifmia[/i] code again.'[br]

Steve Meretzky: '[i]Zifmia[/i], still? Shouldn't that have been fixed?'[br]

Marc Blank: 'I don't know. Dave wrote that part originally.'[br]

Dave Lebling: 'I thought I'd fixed that one! The change must not have persisted...'[p]

Then in an instant they are gone again, leaving you somewhat bewildered as to what just happened."

Report vaguely summoning "[implementors]":

say "Nothing happens any more."

Report vaguely summoning "[other implementors]":

say "For a moment you think you can hear voices, very faintly, but then they are gone again. Their connection to this world is not quite strong enough for them to be summoned through."

Report vaguely summoning "an/a/the/-- implementor/implementer/daniel stelzer/--":

say "A long-haired and slightly dishevelled man materializes suddenly out of the air in front of you. He looks around in confusion for a long moment, muttering quietly to himself. 'Must be a [i]zifmia[/i] spell...but the casting it at action requires the second noun to be in scope. Did something go wrong with the palantir code again?' He pulls out an enormously long scroll of parchment and runs it through his hands until he finds the right spot. 'Ah, here it is...' He scratches something out, then whispers the word [b]compile[/b]. There is a flash of light, and he's gone.";

move the changelog to the location.

Report vaguely summoning "an/a/the/-- implementor/implementer/daniel stelzer/--" when the changelog has been on-stage:

say "Nothing happens. Really. Nothing at all."

There is a changelog. "A scrap of paper lies on the ground, right where the Implementor had been standing." Understand "scrap" or "paper" or "of paper" as the changelog.

The description of the changelog is "Major Changes in Version 2 (Post-IntroComp)

- Replaced Approaches by Emily Short with Distant Movement by Daniel Stelzer (similar functionality, but different interface--let me know what you think of it)

- Overhauled scope rules to allow better disambiguation messages for objects in other locations

- Added caching to scope rules, greatly improving speed

- Completely replaced 'find the vent' puzzle, which didn't make much sense

- Added checkpoints 'prelude', 'adventurer', and 'intermezzo'

- Removed ropes until I can get them working better

- Added ability to erase spell scrolls

- Added new shorthand for metamagic: 'lleps zifmia adventurer', 'yonk malyon dragon'

- Far too many small bug fixes to count[p]".

[Cleesh]

Effect of casting cleesh at a person when the second noun is affected by vardik:

say "You complete the spell, but nothing happens to [the second noun], nothing at all. Strange."

Effect of casting cleesh at the player:

say "You are turned into a newt, and scurry off to find your friends in the swamp. You are distracted by various yummy insects along the way, but eventually settle into a nice gooey part of the morass.";

record "Cleeshed yourself into a newt" as an ending;

end the story saying "You live happily ever after[if a random chance of 1 in 5 succeeds] (until you are devoured by a heron)[end if]".

Effect of casting cleesh at something:

say "The cleesh spell is only designed to affect living things, and so [the second noun] [are] unaffected."

Effect of casting cleesh at a person:

say "[The second noun] looks sort of green and slimy for a moment, but [they] [get] better."

[Vaxum]

Effect of casting vaxum at the player:

say "You feel a little better."

Inverse effect of casting vaxum at the player:

say "You feel a little worse."

[I used to have a system of relations to track people's moods toward the player, but it was unnecessarily complicated for this story.]

[Exex]

Effect of casting exex at something:

say "[The second noun] vibrates for a moment."

Effect of casting exex at a person when the second noun is affected by exex:

say "Nothing further seems to happen yet."

Effect of casting exex at a person:

say "[if the second noun is the player]You feel energetic and zippy.[otherwise][The second noun] shimmers, then vibrates in place for a few seconds, but doesn't seem to take any notice of the change.[end if]";

affect the second noun with exex for 10 turns.

Reset for exex:

if the currently reset object is the player:

say "The effects of the exex spell have worn off. You are ravenous, parched, and tired.";

otherwise if the player can see the currently reset object:

say "[The currently reset object] [seem] to be moving slowly again."

[Ozmoo]

[See GASPAR.]

[Melbor]

[See VARDIK.]

[Izyuk]

Instead of casting izyuk at a person when the second noun is flying and the player is not reversed: say "[The second noun] [are] already flying."

Effect of casting izyuk at something:

say "The [i]izyuk[/i] spell attempts to levitate [the second noun], but without a conscious mind to keep the spell working it fails after a few moments."

Effect of casting izyuk at a person:

say "[if the second noun is the player]You are now floating serenely in midair.[otherwise][The second noun] [rise] a few feet into the air and [hang] there, hovering.[end if]";

affect the second noun with izyuk for 3 turns.

Definition: something is flying: no.

Definition: a person is flying if they are affected by izyuk.

Understand "land" as a mistake ("[if the player is affected by izyuk]You'll have to wait a few minutes until [i]izyuk[/i] wears off.[otherwise]You're already on the ground.").

Instead of sleeping when the player is flying:

say "You'll need to settle down before you can think of settling down."

Reset for izyuk:

if the currently reset object is the player:

say "You settle gently to the ground.";

otherwise if the player can see the currently reset object:

say "The izyuk spell wears off. [The currently reset object] [settle] gently to the ground."

[Filfre]

Effect of casting filfre at:

say "In a blinding burst of pyrotechnics, the air lights up with fireworks and dazzling explosions of multicolored fire! In sizzling sparks and roiling smoke is written:[fixed letter spacing][line break]

[line break]

'This game is an homage[line break]

to the brilliant ENCHANTER trilogy[line break]

by Marc Blank, David Lebling, and Steve Meretzky'[line break]

[line break]

[variable letter spacing]before dying out."

[Kulcad]

Effect of casting kulcad at something:

if the second noun is affected by a spell:

fizzle all spells from the second noun;

say "You feel the weave of magic around [the second noun] come undone as the others spells cease to affect [them]. However, n";

otherwise:

say "N";

say "othing much seems to happen to [the second noun] [themselves]. It seems that [they] [are] mostly nonmagical."

Effect of casting kulcad at a spell scroll:

say "[The second noun] [disintegrate] as [their] magic is destroyed.";

remove the second noun from play.

Effect of casting kulcad at a spell book:

say "[The second noun] [disintegrate] as [their] magic is destroyed.";

remove the second noun from play.

Instead of casting kulcad at the player:

say "You're not sure what would happen, but it most certainly would not be good."

[Guncho]

Effect of casting guncho at something:

say "[The second noun] wavers and disappears.";

remove the second noun from play.

Effect of casting guncho at the player:

say "As you intone the words of the spell, the color seems to drain out of your surroundings. Then suddenly everything goes black.";

record "Gunchoed from this plane" as an ending;

end the story saying "You have left reality behind".