Scroll Thief — 64 of 138

Section C - Spellbreaker

[Blorple]

The Nondescript Room is an unplottable room. "Not quite a [i]room[/i], per se, but that is the best way to describe your surroundings. The whole world seems blurry and vaguely-defined, without real color or composition." The nondescript room has an object called the target.

Mystical concordance relates one thing to another (called the mystical relative). The verb to be mystically linked to implies the mystical concordance relation.

Elemental concordance relates one thing (called the elemental symbol) to one room. The verb to be elementally linked to implies the elemental concordance relation.

Definition: something is mystical if it is mystically linked to something or it is elementally linked to a room.

Definition: a room is mystical if something is elementally linked to it.

To decide what object is the mystical connection of (item - a thing):

if the item is mystically linked to something (called the target), decide on the target;

if the item is elementally linked to a room (called the target), decide on the target;

decide on nothing.

Definition: a room is blorple-forbidden rather than blorple-allowed if it is mystical or it is the nondescript room or it is impassible. [Blorple can't take you to or from such a place.]

Effect of casting blorple at a person:

say "You feel a strange tingling sensation for a moment, but then the spell collapses with a disappointing [i]snap[/i]."

Effect of casting blorple at something:

if hard mode is true: [Can't use the nondescript room teleportation trick here.]

say "Your surroundings seem to shift, momentarily becoming vague and undefined. But then it passes and your vision clears.";

rule succeeds;

say "[one of]You have the strange sensation of being drawn into [the second noun], the world around you distorting and shifting until you find yourself in[or]Your surroundings shift[stopping]...";

now the target of the nondescript room is the second noun;

if the player encloses the second noun, move the second noun to the holder of the player;

move the player to the nondescript room;

magically pull everything else along.

Effect of casting blorple at something when the location is blorple-forbidden (this is the can't blorple in a mystical area rule): say "Nothing happens. Perhaps the spell would work better somewhere else."

Instead of going when the location is the nondescript room:

take full time;

if there is an other thing in the nondescript room:

say "You begin to move, but [the list of other things in the nondescript room] seem to stay right with you, and nothing really changes." instead;

say "You begin to move forward, and the vagueness distorts around you, resolving into faint outlines, then the solid forms of...";

let the place be the target of the nondescript room;

while the place is not a room and the place is not enterable:

let the place be the holder of the place;

move the player to the place;

magically pull everything else along;

now everything in the nondescript room is nowhere. [Just a precaution, this should never happen.]

Definition: something is other if it is not the player.

Definition: something is another if it is not the player.

To magically pull everything else along:

if the second noun is tied up:

repeat with the item running through things tied to the second noun:

if the item is the player or the item is enclosed by the player: [If it would be tied to something problematic, remove it.]

now the second noun is not tied to the item;

repeat with the coil running through ropes enclosed by the player: [Don't allow carried ropes to bypass this.]

if the coil is tied to the player, next;

repeat with the item running through nonrope things which are tied to the coil:

unless the item is enclosed by the player:

say "[The coil] [are] pulled sharply from your hands.";

move the coil to the holder of the item;

break;

if an other thing is tied to the player: [First, remove fixed-in-place objects.]

repeat with the item running through other things tied to the player:

if the item is fixed in place or the item is scenery [and the item is not the strongbox]:

now the item is not tied to the player;

if an other thing is tied to the player: [Now if there's anything left, pull it along.]

say "[The list of other things tied to the player] [appear] beside you[first time]. Apparently your blorple spell affected the rope as well[only].";

repeat with the item running through other things tied to the player:

move the item to the location.

Effect of casting blorple at a mystical thing:

say "[one of]You have the strange sensation of being drawn into [the second noun], the world around you distorting and shifting until you find yourself in[or]Your surroundings shift[stopping]...";

let the far side be the mystical connection of the second noun;

if the far side is a room:

if the second noun is portable:

remove the second noun from play;

otherwise:

if the second noun is enclosed by the player:

move the second noun to the holder of the player;

let the far side be the holder of the far side;

if the far side is a person:

say "[The far side] [jump] back as you appear.";

let the far side be the holder of the far side;

if the far side is not a room and the far side is not enterable:

say "The vague outlines of [the far side] begin to appear around you, but fade away before they fully resolve.";

rule succeeds;

move the player to the far side;

magically pull everything else along;

award points for "exploring mystical connections".

Effect of casting blorple at an inactive scrying device:

say "You feel yourself being drawn towards [the second noun], being pulled into it...but something isn't quite right, and the magical connection fades."

After going from a mystical room (called the place):

if the elemental symbol of the place is off-stage:

say "As you leave, [the elemental symbol of the place] reappears in your hand.";

move the elemental symbol of the place to the player;

continue the action.

[Lesoch]

Definition: something is blowable:

if it is fixed in place, no;

if it is scenery, no;

if it is a person, no;

yes.

To decide what object is the discard destination of (the stand - a thing):

let the place be the holder of the stand;

while the place is not a container and the place is not a supporter and the place is not a room and the place is not a vehicle:

now the place is the holder of the place; [Don't put it in an impossible place.]

decide on the place.

Effect of casting lesoch at a room:

if the second noun is the location:

say "Slowly, teasingly, a small puff of wind begins to blow. It swirls around you, increasing in strength for a moment, then subsides.";

if the player is flying, say "You cautiously let go of your handhold and float back toward the middle of the area.";

otherwise:

say "You feel the wind fluttering through your mind for a moment, though the air around you is still.";

let the wind flag be false;

let the order flag be false;

repeat with the stand running through supporters in the second noun:

repeat with the item running through blowable things on the stand:

if a random chance of 2 in 3 succeeds:

now the wind flag is true; [This means we found something, and the text will change.]

move the item to the discard destination of the stand;

otherwise:

now the order flag is true; [This means something was not affected, by random chance.]

if the wind flag is true, say "Looking around, [if the second noun is the location]the room[else][the second noun][end if] looks somewhat messier than before[if the second noun is the spell research room and the scribbled scroll was on the workbench and the scribbled scroll is not on the workbench]. The wind blew various bits of debris off the workbench[--]including the scribbled scroll[end if].";

if the order flag is true, say "The wind wasn't particularly powerful, however, and you're left feeling slightly disappointed in the result. Perhaps if you tried again."

Empowered effect of casting lesoch at a room:

if the second noun is the location:

say "For a moment nothing happens. Then with a terrifying abruptness gale-force winds begin to appear out of nowhere, whipping the air around you into a veritable tornado for a moment. Then just as quickly it subsides.";

if the player is flying:

say "Floating in midair, however, you are powerless to resist the storm as it hurls you with great force into the wall.";

record "Launching yourself into a wall" as an ending;

end the story saying "You have died";

rule succeeds;

otherwise:

say "You simultaneously feel wind and no wind around you. The room is still, but [the second noun] is suddenly wracked by an enormous gale.";

let the wind flag be false;

repeat with the stand running through openable unlocked containers enclosed by the second noun:

if a random chance of 1 in 3 succeeds:

now the wind flag is true;

now the stand is open;

repeat with the stand running through open containers enclosed by the second noun:

repeat with the item running through blowable things in the stand:

if a random chance of 2 in 3 succeeds:

now the wind flag is true;

move the item to the discard destination of the stand;

repeat with the stand running through supporters enclosed by the second noun:

repeat with the item running through blowable things on the stand:

now the wind flag is true; [This means we found something, and the text will change.]

move the item to the discard destination of the stand;

if the wind flag is true, say "As you regain your balance, you notice that [if the second noun is the location]the room[else][the second noun][end if] seems quite a bit messier than before."

Effect of casting lesoch at something:

say "Disappointingly, [the second noun] [seem] mostly unaffected by the breeze."

Effect of casting lesoch at a supporter:

say "A thin, narrow breeze sweeps across [the second noun][if there is a blowable thing on the second noun], brushing [the list of blowable things on the second noun] off the edge[end if].";

let the place be the discard destination of the second noun;

repeat with the item running through blowable things on the second noun:

move the item to the place.

Effect of casting lesoch at an open container:

say "A thin, narrow breeze sweeps into [the second noun][if there is a blowable thing in the second noun], swirling around and tossing [the list of blowable things in the second noun] out[end if].";

let the place be the discard destination of the second noun;

repeat with the item running through blowable things in the second noun:

move the item to the place.

Inverse effect of casting lesoch at:

say "The air goes absolutely still for a moment."

[Jindak]

A thing can be magical or nonmagical. A thing is usually nonmagical.

A spell scroll is usually magical. A spell book is usually magical.

Definition: a thing is apparently magical if it is magical or it is affected by a spell.

Effect of casting jindak at a room:

if the player can see something apparently magical:

say "[The list of visible apparently magical things] [glow] faintly blue.";

otherwise:

say "Nothing glows."

Effect of casting jindak at an apparently magical thing:

say "[The second noun] [flash] blue."

[Caskly]

[See KREBF]

[Throck]

Effect of casting throck at a person:

say "The spell doesn't seem to do anything to [the second noun], perhaps because [they] [are] not a plant."

[Espnis]

Effect of casting espnis at a person:

say "[The second noun] [look] a little bit sleepy."

[Liskon]

[I don't know how this could be implemented...if I need it I'll use a special case.]

[Tinsot]

[Same as LISKON, I don't know how I'll handle fluids.]

[Snavig]

[Nothing in general.]

[Girgol]

[I tried to write this one, but time is so intrinsic to Inform that I was unable to. Spellbreaker is getting stiffed on spells, it seems...]