Scroll Thief — 71 of 138
Daniel M. Stelzer
Section 1 - The Journal
In the bag is something called your journal. The description of your journal is "This is the journal in which you have kept meticulous notes and personal recollections through your years at the University. With amazing foresight you prepared a helpful index page at the back, which you updated every time you added a significant entry. You've also set a few pages aside in case you need to write anything in the journal tonight, under the heading [i]Burglary Notes[/i]." It is ropable.
The helpful index is part of your journal. The description of the helpful index is "[index listing]".
After examining the journal when the journal was unexamined:
suggest the command "LOOK UP (X) IN JOURNAL".
To say index listing:
say "It's a good thing you wrote this, because your ingenious 'colors-starting-with-C' page numbering system makes little sense even to yourself at this point.[p]";
say "[tt]Index:[/tt][br]";
repeat with X running through journal entries:
say " [tt][X][/tt][br]";
say "[line break]There are also various class notes interspersed between these.";
suggest the command "LOOK UP (X) IN (Y)".
Instead of consulting your journal about a topic listed in the Table of Textual Journal Entries:
take full time;
say "[topic understood]: '[description entry]'[p]".
Instead of consulting your journal about "the/-- index":
say "(looking at the index)[ccb]";
try examining the index.
Instead of consulting your journal about "burglary notes/--":
say "(looking at the burglary notes)[ccb]";
try examining the burglary notes.
Instead of consulting your journal about a topic:
take full time;
say "You flip through the pages, but see nothing important under '[topic understood]'. You might want to look at the index."
Instead of consulting the index about a topic:
now the noun is the journal;
continue the action.
A journal entry is a kind of value. The journal entries are defined by the Table of Journal Entries.
Table of Journal Entries
| journal entry | description |
| crimson | "First entry. Thaumaturgy classes begin tomorrow! Not much else to say." |
| coral | "The tedium of Magic Theory 101 is at an end! I think I can summarize everything we learned in that class in one paragraph: There are three parts to any spell: the [b]Incantation[/b] and the [b]Unusual Effect[/b] are obvious, but there is also the [b]Presence[/b] which fuels the magic. The [b]Presence[/b] (which must always be pronounced dramatically for some reason) is imbued into the vellum of a scroll, which is why the scroll is consumed as the spell is cast, and also why we can't just copy powerful spells onto every sheet of parchment we see. How did that explanation merit a full semester of lectures?!" |
| canary | "This semester's schedule is harder than I'd thought. Curses 216 sounded interesting, and the professor is great, but so far it's mostly been an exercise in frustration. I just can't get my head around some of these problem sets. And Magic Theory 102 is only slightly more interesting than 101. At least in this class we get to learn more about the history of the spells. It seems that Bizboz was the first person to write about thaumaturgy, in the aptly-named [']On the Presence of Incredibly Weird Stuff Going On['], and was ostracized for it." |
| chartreuse | "This lecture seems to be worth a note. When you see an Enchanter going around with a spell book, they aren't actually just storing their spell scrolls in a clever way: the pages of a spell book are made with an enormous amount of [b]Presence[/b], such that the spells can actually be cast repeatedly without destroying the book! The downside is that casting a spell from a spell book is a lengthier process. The Enchanter first needs to go through a [b]Primary Incantation[/b], or 'memorization', which calls the [b]Presence[/b] from the book and stores the almost-completed spell in the caster's mind. The spell can then be cast later with the [b]Secondary Incantation[/b], most often a single word, which finishes the [b]Incantation[/b] and causes the [b]Unusual Effect[/b]. Apparently the mechanism behind this was discovered a long time ago, then put into practice by a scrollwriter named Berzio a long time ago, with the creation of the [i]gnusto[/i] spell." |
| celadon | "Today I cast my first spell! Magic Theory 241 is the best class I've taken so far. After weeks of practicing the pronunciation of the ancient words, we were each given a [i]frotz[/i] scroll and allowed to cast it under close supervision. I got the proper effect on my first try at casting it, and this journal is still glowing as I write this! My faith in the Thaumaturgy program has been restored. We then had an interminable lecture on its history. One of the first versions was [i]noside[/i], which would only affect objects already prepared with other spells. Then [i]chiaro[/i] was invented, which worked on any inanimate object, and [i]blort[/i], which allows one to see in complete darkness...and so on and so on. But we got to use magic! Weak basic magic, but magic nonetheless!" |
| cyan | "So close...and yet so far. I know I can do magic! I've used every practice scroll perfectly! And [i]still[/i] they won't trust us with the [i]gnusto[/i] spell! Without [i]gnusto[/i] I will never be able to use magic outside the carefully regulated classroom environment, and even if I managed to purloin a scroll it would only be one casting of [i]frotz[/i] or [i]gloth[/i]. GAH!" |
| cerulean | "This is it. G.U.E. Tech is closing. [bracket]The text degenerates into dramatically illegible scribblings, and you can't remember what else you intended to write on this page.[close bracket]" |
Table of Textual Journal Entries
| topic | description |
| "notes" or "class notes" | "Starting on page 1...'[p](If you want to look up a topic, you'll need to be more specific.)" |
| "xyzzy/plugh/teleportation spell/spells/--" | "See: [']teleportation['].' You look back through your notes and find the lecture on teleportation spells. Ah, here it is...[p]Someone once stood four and a half feet away from the center of the [i]xyzzy[/i] spell, so only part of her arrived at the destination. This is why modern teleportation spells are legally required to have additional checks against 'portal-slicing'." |
| "portal-slicing" or "portal slicing" | "Portal slicing is when a teleportation spell affects only part of an object, leaving the rest behind. You didn't write down much about this topic, except to note that an attempt was once made to weaponize this effect." |
| "rezrov" | "A common spell used to open locked objects. It apparently took a long time to perfect, because of all the possible ways an object could be 'opened' and the different methods needed for each. It was then nearly ubiquitous for a time before new laws prevented non-Enchanters from obtaining it." |
| "berzio potion/--" | "[i]Berzio[/i] potions were named after the famed wizard Berzio, who went without food or drink for days while perfecting the [i]gnusto[/i] spell. After drinking one of these potions, a person ceases to feel hungry or thirsty until it wears off." |
Looking up it in is an action applying to one journal entry and one thing and requiring light. Understand "look up [journal entry] entry/--" or "look [journal entry] up" or "look up [journal entry] entry/-- in [the journal]" or "read [journal entry] entry/--" or "examine [journal entry] entry/--" or "x [journal entry] entry/--" as looking up it in.
Understand "consult [the journal] about [journal entry] entry/--" as looking up it in (with nouns reversed).
Rule for supplying a missing second noun when looking up: [This isn't important as the noun is never used, but all actions need to fill out their nouns/second nouns.]
now the second noun is the journal.
Check looking up a journal entry in the journal:
if the player cannot see the journal, say "You would need your journal for that." instead.
Carry out looking up a journal entry in the journal:
say "[journal entry understood]: '[description of the journal entry understood]'[p]".
[I can't add new grammar lines to the 'consulting' action with a rule for supplying a missing noun, because when only one thing is supplied it needs to be the first argument, not the second. So this workaround.]
Researching is an action applying to one topic and requiring light. Understand "look up [text]" or "look [text] up" as researching.
Check of researching a topic:
if the journal is visible:
say "(in the journal)[ccb]";
try consulting the journal about the topic understood instead;
otherwise if the Encyclopedia is visible:
say "(in the Encyclopedia)[ccb]";
try consulting the Encyclopedia about the topic understood instead;
say "You don't have a reference book handy." instead.
The burglary notes are part of the journal. The burglary notes have some text called the records. The description of the burglary notes is "[i]Burglary Notes:[br][records of the burglary notes][/i]".
Writing it in is an action applying to one topic and one thing and requiring light. Understand "write [text] in/on [something]" or "record [text] in/on [something]" as writing it in.
Check someone writing a topic in something (this is the NPCs can't write rule):
if the player can see the actor, say "[The actor] [don't] seem like much of a calligrapher.";
stop the action.
Check writing a topic in something when the player does not carry a copying tool:
if the player can touch a copying tool (called the pen), carry out the implicitly taking activity with the pen;
if the player does not carry a copying tool, say "You can't write anything without a pen of some sort." instead.
Check writing a topic in a spell scroll: say "You can't just write anything you want on a magically-prepared spell scroll; you need to copy a spell from another source." instead.
Check writing a topic in a spell book: say "The pages of a spell book are filled with enough magic that they cannot be written on normally. That's why the [i]gnusto[/i] spell was invented." instead.
Check writing a topic in a library book: say "The penalties for defacing library books are very harsh." instead.
Last check writing a topic in something which is not writable: say "[The second noun] [don't] make a very good writing surface." instead.
Definition: something is writable if it is the burglary notes or it is the featureless white cube.
Should the game suggest writing a topic in a writable thing: it is a good suggestion.
Understand "write in/on [something]" as a mistake ("You need to specify the text you want to write, as in WRITE 'NEED TO BYPASS THE OCELOTS' IN MY BURGLARY NOTES'.").
Instead of writing a topic in the journal:
say "(in the burglary notes)[ccb]";
now the second noun is the burglary notes;
continue the action.
Carry out writing a topic in the burglary notes:
let X be the records of the burglary notes;
now the records of the burglary notes are the substituted form of "[X][br][topic understood]".
Report writing a topic in the burglary notes:
say "You append [i][topic understood][/i] to your burglary notes."
Instead of putting the correction film on the burglary notes: try rubbing the burglary notes.
Instead of rubbing the burglary notes: say "You eradicate your burglary notes."; now the records of the burglary notes are ""; take full time.