Scroll Thief — 10 of 138

Section H - Modifications to Standard Actions

Understand "examine [things]" or "look at [things]" as examining.

Understand "open [things]" as opening. Understand "close [things]" as closing.

Instead of pushing or pulling or turning an open door: try closing the noun.

Instead of pushing or pulling or turning a closed door: try opening the noun.

Rule for deciding whether all includes a person while an actor dropping or an actor throwing or an actor inserting or an actor putting (this is the new exclude people from drop all rule): it does not.

Rule for deciding whether all includes scenery while an actor taking or an actor taking off or an actor removing (this is the new exclude scenery from take all rule): it does not.

Rule for deciding whether all includes fixed in place things while an actor taking or an actor taking off or an actor removing (this is the new exclude fixed in place things from take all rule): it does not.

Rule for deciding whether all includes people while an actor taking or an actor taking off or an actor removing (this is the new exclude people from take all rule): it does not.

The new exclude people from drop all rule is listed instead of the exclude people from drop all rule in the for deciding whether all includes rulebook.

The new exclude scenery from take all rule is listed instead of the exclude scenery from take all rule in the for deciding whether all includes rulebook.

[The new exclude fixed in place things from take all rule is listed instead of the (exclude fixed in place things from take all rule) in the for deciding whether all includes rulebook.] The new exclude people from take all rule substitutes for the exclude fixed in place things from take all rule. [See Inform bug #0001714.]

The new exclude people from take all rule is listed instead of the exclude people from take all rule in the for deciding whether all includes rulebook.

Last after someone going when the action is not silent (this is the slight extension to the describe room gone into rule): [Normally the report rules don't run if the actor isn't in scope at the *beginning* of the action. This adds a response if an actor comes into a room the player can see, from a room they can't.]

let the start point be the room gone from; [Inform was choking on the sentences so I rephrased slightly with these temporary variables.]

let the end point be the room gone to;

if the start point is the location or the end point is the location, make no decision;

recalculate scope; [Update our record of which rooms are light-filled.]

if the start point is marked in scope and the end point is not marked in scope:

say "[The actor] [leave] [the room gone from], heading [noun].";

rule succeeds;

if the end point is marked in scope and the start point is not marked in scope:

let the back way be the opposite of the noun;

if the back way is up:

say "[The actor] [enter] [the room gone to], coming from above.";

otherwise if the back way is down:

say "[The actor] [enter] [the room gone to], coming from below.";

otherwise:

say "[The actor] [enter] [the room gone to], coming from [the back way].";

rule succeeds;

continue the action.

Understand "roll [something]" as turning.