Scroll Thief — 82 of 138

Book III - The Adventurer

Part 1 - The Scrying Room

Section A - Scrying

The scrying flag is a truth state that varies. [This prevents infinite recursion.] The scrying flag is false.

The current viewpoint is an object that varies. The current viewpoint is yourself.

A scrying device is a kind of thing. A scrying device can be active or inactive. Instead of switching on or switching off a scrying device: say "You don't see any obvious way.". A scrying device is usually magical, addressable, and translucent.

A scrying mirror is a kind of scrying device. A scrying mirror is usually inactive, fixed in place, and scenery. The plural of scrying mirror is asdfasdfasdf. [1]

A palantir is a kind of scrying device. A palantir is usually active and portable. [A palantir is always portable.] Understand "palantir" or "sphere" or "ball" as a palantir. The plural of palantir is palantiri. Understand "palantiri" or "spheres" or "balls" as the plural of a palantir.

Before listing contents while taking inventory: group palantiri together as "palantiri".

Effect of casting kulcad at a magical scrying device:

say "[The second noun] flares with light for a moment, bright spears of fire streaking through the glass. A spiderweb of glowing lines fills its surface. Then all at once it goes dark, the crystal shattering into thousands of pieces.";

now the second noun is not magical;

now the second noun is damaged;

announce the mirror breaking.

Definition: a scrying device (called the glass) is usable rather than unusable if it is active and it is undamaged and the mystical relative of the glass is undamaged. [Turned on, and both ends in working order.]

[Allowing one to say passwords to mirrors.]

Understand "say [text] to [scrying mirror]" or "speak [text] to [scrying mirror]" as answering it that (with nouns reversed). Understand "tell [scrying mirror] [text]" as answering it that.

Instead of telling a scrying mirror about a topic:

try answering the noun that (the topic understood).

Indirect visibility relates various things to various scrying devices. The verb to be seen through means the indirect visibility relation. The verb to show means the reversed indirect visibility relation.

Understand "through [something related by indirect visibility]" or "via [something related by indirect visibility]" or "in [something related by indirect visibility]" as a thing.

Understand "indirvis" as a mistake ("[indirvis]").

To say indirvis:

show relation the indirect visibility relation.

To activate (the glass - a scrying device): [These phrases make sure both ends are in sync.]

now the glass is active;

now the mystical relative of the glass is active.

To deactivate (the glass - a scrying device):

now the glass is inactive;

now the mystical relative of the glass is inactive.

A thing can be scriable or unscriable. A thing is usually scriable. A scrying device is never scriable. [This prevents another sort of infinite recursion.]

Scope adjustment (this is the look through scrying devices rule):

if the security lockdown is happening, make no decision; [Scrying devices don't work during this time.]

repeat with the glass running through scrying devices: [Reset the relation first.]

now the glass does not show anything;

repeat with the glass running through usable visible scrying devices: [Now add in the other objects.]

let the far glass be the mystical relative of the glass;

if the far glass is off-stage:

deactivate the glass;

next;

let the far side be the visibility ceiling of the far glass;

if the far side is nothing:

deactivate the glass;

next;

now the far side is marked in scope;

repeat with the item running through scriable things enclosed by the far side:

if the far glass can see the item:

now the item is marked in scope;

now the glass shows the item;

repeat with the item running through scriable doors liminal to the far side:

if the far glass can see the item:

now the item is marked in scope;

now the glass shows the item;

now the nonlocal visibility flag is true.

Include (-

[ VisibilityCeiling obj l up;

up = obj;

l = obj;

while (true){

up = VisibilityParent(up);

if (up == 0) break;

l = up;

}

return l;

];

-).

To decide what object is the visibility ceiling of (O - an object):

(- VisibilityCeiling({O}); -).

The temporary scrier is a privately-named scenery person. [The player is changed to this person to show a different viewpoint through a scrying device.]

Instead of examining or searching a scrying device (called the glass):

take full time;

if the glass is not magical, say "Nothing appears any more.";

if the glass is damaged, say "The glass is shattered and covered in cracks. It seems to reflect a strange flickering darkness, like ash in water." instead;

if the glass is inactive, follow the mirror description rule instead;

if the mystical relative of the glass is damaged, say "Instead of a reflection, [the glass] shows a strange vision: a web of thin black shadows, with swirls of color twisting between them like oil on water." instead;

if the security lockdown is happening, say "[The glass] [show] only the words [tt]SECURITY LOCKDOWN - SCRYING PREVENTED[/tt] in glowing red letters." instead;

let the far glass be the mystical relative of the glass;

let the far side be the holder of the far glass;

let the far ceiling be the visibility ceiling of the far glass;

if [the far glass is off-stage or] the glass can see the far glass:

say "Through [the glass] you see only darkness.";

rule fails;

if the far ceiling is darkness-filled:

say "You can make out the dim outlines of [the far ceiling], but it is too dark to perceive any details.";

rule fails;

say "Instead of a reflection, [the glass] seems to show a different view, as if it were a window to another world...";

let the current location be the player;

let V be false;

if the location of the far glass is visited, let V be true; [Remember this to switch it back later.]

now the scrying flag is true; [This flag is also used to avoid showing mirrors recursively.]

now the current viewpoint is the far glass;

move the temporary scrier to the far side;

now the player is the temporary scrier;

try looking;

now the player is the current location;

remove the temporary scrier from play;

now the current viewpoint is the player;

now the scrying flag is false;

say "...you step back from the glass, and take a moment to regain your bearings.";

[move the player to the current location, without printing a room description;]

if V is false, now the location of the far glass is unvisited. [If the player hasn't been there in person, it shouldn't be marked as 'visited' from this.]

Should the game suggest searching a scrying device: it is a good suggestion.

After reading a command (this is the avoid unpleasant LOOK IN disambiguation rule): [HACK HACK HACK]

while the player's command includes "look in ":

replace the matched text with "look into ".

Instead of attacking a scrying device (this is the glass is sharp rule): say "Smashing [the noun] might be cathartic; removing the slivers of glass from your hands, less so. Enchanters are supposed to always keep their self-control."

Carry out an actor throwing something heavy at to a scrying device (this is the glass is fragile rule):

now the second noun is damaged;

announce the mirror breaking;

if the player can see the second noun:

say "[The second noun] [shatter] spectacularly under the weight of [the noun], points of light scattering through the room as a spiderweb of cracks splits the reflection into slivers.";

if the player can see the mystical relative of the second noun and the second noun is active:

let the glass be the mystical relative of the second noun;

say "[The glass] [flare] with light as [their] image dissolves. Now [they] [reflect] a swirl of brilliant colors divided by thin lines of shadow.".

Carry out an actor throwing a scrying device at to something (called the hard surface) when the hard surface is fixed in place or the hard surface is scenery and the hard surface is substantial (this is the glass can be thrown rule):

now the noun is damaged;

announce the mirror breaking;

if the player can see the noun:

say "There is a sharp [i]crack[/i] and fissures spread through [the noun].";

if the player can see the mystical relative of the noun and the noun is active:

let the glass be the mystical relative of the noun;

say "[The glass] [flare] with light and [emit] a dull [i]thud[/i], [their] reflection dissolving into vague swirls of color.".

To announce the mirror breaking:

display the boxed quotation "Out flew the web and floated wide;

The mirror crack'd from side to side...

-- The Lady of Shalott, Alfred Lord Tennyson".