Scroll Thief — 113 of 138

Daniel M. Stelzer

Release 2

Book II - Expanding the Storage Area

Chapter 1 - Doors

Closet-puzzle is a puzzling scene with puzzle description "figuring out where the objects in the closet went". Closet-puzzle begins when the markings in the dust are examined. Closet-puzzle ends when the hidden door is present.

Effect of casting vezza at the Disused Closet: say "The markings on the floor have been swept away, but nothing else has changed."

Inverse effect of casting vezza at the Disused Closet: say "Three people wearing librarians['] cloaks are moving wooden storage boxes, packing them into a larger crate. Then one of them claps three times, and a section of the wall swings outward. The others slide the crate through some sort of door, and the wall swings closed behind them."

Empowered effect of casting vezza at the Disused Closet: say "A broken shelf from the Main Stacks has been pushed against the southeast wall."

When play begins: [This property needs to be set at run-time for I6 reasons.]

now the hidden door is absent;

now the secret door is absent.

There is a door called a hidden door. The initial appearance of the hidden door is "A section of the wall has opened up to the southeast, revealing a hidden door." It is southeast of the Disused Closet and northwest of the Secret Tunnel.

There is a door called a secret door. It is southwest of the Secret Tunnel and northeast of the Storage Area. The initial appearance of the secret door is "A section of the wall has opened up to the northeast, revealing a secret door."

Rule for writing a paragraph about the hidden door when the location is the Secret Tunnel: now the hidden door is mentioned.

Rule for writing a paragraph about the secret door when the location is the Secret Tunnel: now the secret door is mentioned.

Clapping is an action applying to nothing. Understand "clap" or "applaud" as clapping.

Report clapping: say "You clap loudly."

Report someone clapping: say "[The actor] [clap] [their] hands together."

Understand "clap [number] time/times" as a mistake ("[note][bracket]I have tried to get the parser to understand such commands, but with no success. Just type three separate commands. Sorry![close bracket][/note]").

After an actor clapping when the hidden door is absent and the actor is enclosed by the Disused Closet for the third turn:

if the player can see the actor or the player is the actor, say "[The actor] [clap] loudly...and [hear] a rumbling from the [if the location is the disused closet]southeast[else]northwest[end if]. A section of the wall swings aside, revealing a hidden door. That's odd. Why would it need to be hidden?";

now the hidden door is present;

award points for "[if the player is not the actor]indirectly [end if]discovering a hidden door".

After an actor clapping when the secret door is absent and the actor is enclosed by the Storage Area for the third turn:

if the player can see the actor or the player is the actor, say "[The actor] [clap] loudly...and a secret door is revealed[if the location is the storage area], hidden behind the piles of junk[else] in the southwest wall[end if].";

now the secret door is present;

award points for "[if the player is not the actor]indirectly [end if]discovering a secret door".

After an actor clapping when the actor is enclosed by the Secret Tunnel for the third turn:

if the player can see the actor or the player is the actor:

say "[The actor] [clap] loudly...[r]";

if the secret door is absent or the hidden door is absent:

say "and you hear a faint rumbling from the northwest and southeast, but no doors materialize.";

otherwise:

say "but nothing out of the ordinary happens.";