Scroll Thief — 112 of 138

Daniel M. Stelzer

Release 2

Chapter 1 - The Piles of Junk

Some piles of junk are fixed in place in the Storage Area. [The piles are a container.] Understand "pile" or "heap" or "clutter" or "objects" or "object" or "strange" as the junk.

Rule for writing a paragraph about the piles of junk:

say "Around the table, strange objects are piled almost four feet high. You don't even recognize what most of it is, much less what might be useful or magical.".

After choosing notable locale objects for the Storage Area:

set the locale priority of the piles of junk to 1;

make no decision.

Temporary storage is a container.

The description of the piles is "You can't recognize much of this stuff at a cursory glance. You'd need to search through it to find something potentially interesting."

Instead of taking or searching the piles of junk:

take full time;

if a random chance of one in three succeeds:

say "You look through the pile, but don't find anything particularly interesting with a cursory glance.";

rule succeeds;

let the item be a random nonmagical thing in temporary storage;

if the item is nothing:

say "You sift through the piles, but find nothing of interest.";

rule succeeds;

say "You sift through the piles and find [an item].";

now the player carries the item.

Instead of the Adventurer taking or searching the piles of junk:

take full time;

say "[The Adventurer] searches for a minute, seeming to focus primarily on small shiny objects. But [he] doesn't seem to find anything of real interest to you.";

record the Adventurer's attempt as successful.

Instead of an actor putting or inserting something into the piles:

take full time;

if the player can see the junk, say "[The noun] [disappear] into the junk.";

if the noun is a palantir and the player can see the mystical relative of the noun, say "[The mystical relative of the noun] [show] a fuzzy image for a moment, then static, then nothing[first time]. All the residual magic in the piles must be interfering with the connection[only].";

move the noun to temporary storage.

Instead of an actor dropping something in the Storage Area:

try the actor inserting the noun into the piles.

Effect of casting jindak at the piles:

say "Glimmers of blue appear from inside the pile. [r]";

if the location is the Storage Area:

if the featureless white cube is in temporary storage: [Give the cube first.]

say "You begin to rummage through the pile, and find a strangely featureless white cube glowing intensely.";

now the player carries the featureless cube;

award points for "discovering a featureless white cube";

rule succeeds;

let the item be a random magical thing in temporary storage;

if the item is nothing:

say "You try to find what was glowing, but the spell fades before you reach it.";

otherwise:

say "Before the spell fades, you rummage through the pile and find [an item].";

move the item to the player;

otherwise:

say "From here, however, you aren't able to tell what the source of the glow might be."

Empowered effect of casting jindak at the piles when the location is the Storage Area: say "Something within the pile shines more brightly, but the junk shifts as you move towards it and the glow is lost within the pile again." [Override the message in one specific case with yonk.]

Effect of casting jindak at the Storage Area:

say "Thin flickers of blue flare within the piles of junk, though you can't tell precisely what caused them. If you focused your spell more precisely you might be able to find whatever it was."

[Most of these are shout-outs.]

In temporary storage is an old floor waxer. The description of the waxer is "[tt]Built by the FROBOZZ MAGIC FLOOR WAX COMPANY[/tt]". The waxer is ropable. [Sorcerer]

In temporary storage is a dented brass lantern. The description of the dented lantern is "You'd be surprised if it worked at all any more...but there's no way to tell, as you don't see a switch." [Adventure]

In temporary storage is a rusty knife. The description of the rusty knife is "The knife looks dangerous, if only because of the risk of tetanus." Instead of throwing the knife at something: say "You change your mind at the last moment. Old residual spells can stay on objects like this for quite a while." [Zork]

In temporary storage is a blue cable. The description of the cable is "A short length of copper wire with some sort of blue coating." [Suspended]

In temporary storage is a brown spool. The description of the spool is "There's no way to tell what might once have been stored on it." [Planetfall]

In temporary storage is a wooden octahedron. The description of the octahedron is "A large die for some sort of game, perhaps? But there are no numbers on the faces." [Metamorphoses] Understand "die" or "d8" as the octahedron. Instead of turning the octahedron: say "You toss it to the ground, and it comes up...blank. How useless."; take full time. [This is a reference to the unmarked coins in Balances.]

In temporary storage is a misshapen hourglass. The description of the hourglass is "It looks something like an hourglass, but both ends are open and one is significantly larger than the other." The hourglass is ropable. [Metamorphoses again]

In temporary storage are a pair of tap shoes. The description of the tap shoes is "Worn leather shoes with some odd metal plates attached to the soles." [just a red herring] The tap shoes are wearable.

In temporary storage is a rusty iron rod. It is magical. The description of the rod is "About two feet long, with a sort of star on the end." [Adventure]

Effect of casting kulcad at the magical iron rod:

say "Nothing obvious happens to the rod.";

now the rod is nonmagical.

In temporary storage is a featureless white cube. It is magical. [Spellbreaker]

The featureless white cube has some text called the name. Understand the name property as describing the cube. The printed name of the white cube is "[if the name of the cube is empty]featureless white[else]'[name]'[end if] cube".

Carry out writing a topic in the featureless white cube:

say "You write '[topic understood]' on one side of the cube[if the name of the cube is not empty], erasing '[name of the cube]'[end if].";

now the indefinite article of the cube is "the";

now the name of the cube is the substituted form of "[topic understood]".

Instead of rubbing the featureless white cube:

say "You rub the cube, leaving its surface smooth and clean.";

now the indefinite article of the cube is "a";

now the name of the cube is "";

take full time.

Should the game choose when comparing the featureless white cube against the display case: it is a good choice.

Should the game choose when comparing the featureless white cube against the aquarium: it is a good choice.

Should the game choose when comparing the featureless white cube against the shattered display case: it is a good choice.

Effect of casting kulcad at the featureless white cube: [Ooh boy...]

say "As you try to undo the spells on the cube, a power you've never felt before lashes back at you, singing your hands and burning the scroll to ash. This is no ordinary magic."

Understand "juggle" or "juggle [things]" as a mistake ("You would probably just drop everything.").