Section C - Fissure Puzzle
Instead of throwing something at west from the East Edge:
say "That might not be a good idea. The rocks here are uneven, and [the noun] might roll into the fissure[if the noun is a palantir]. Even if you could get it back with [i]blorple[/i], it might fall into a small crevice or break against a rock[end if]."
Instead of facing west in the East Edge when the bridge is absent: say "You can barely see the other side through the mist."
Instead of facing east in the West Edge when the bridge is absent: say "You can barely see your starting point through all the mist."
Definition: a room is fissure-adjacent if it is the West Edge or it is the East Edge.
Effect of casting golgatem at a fissure-adjacent room when the crystal bridge is off-stage:
say "A tracery of blue-white lines materializes above the fissure, growing and thickening until a beautiful crystal bridge hangs apparently unsupported above the fissure.";
now the crystal bridge is in all fissure-adjacent rooms;
Inverse effect of casting golgatem at a fissure-adjacent room when the crystal bridge is on-stage:
say "The bridge dissolves into nothingness.";
now the crystal bridge is nowhere.
Instead of waving the rod when the location is fissure-adjacent: say "You wave the rod...and nothing happens. [one of]You feel vaguely disappointed[or]You aren't sure what you expected, maybe a [i]golgatem[/i] spell or something? Something magical[or]Oh well[stopping]."; take full time.
A rusty spike is fixed in place in the Damp Cavern. "A rusty spike has been driven into the rock[if the damp paper is fixed in place], pinning [a damp paper] to the wall[end if]." The description of the rusty spike is "A short length of iron, pounded into a small gap in the rock."
A damp paper is fixed in place in the Damp Cavern. The description of the paper is "A short note has been scrawled across the paper:[p][i]To the next expedition: we tried the [/i]golgatem[i] spell here, and the mist is sufficient to create a bridge. Had to leave off before variations could be tested. TODO. - A. Schultz[/i][p]There also seems to be something printed on the back.". Understand "note" as the paper. The paper is light.
The paper-back is part of the paper. The printed name of the paper-back is "back of the paper". Understand "back" or "of [the paper]" or "printed" as the paper-back. Should the game suggest doing something with the paper-back: it is a bad suggestion. The paper-back is privately-named.
Setting action variables for doing anything except examining when the noun is the paper-back: now the noun is the paper.
Setting action variables for doing anything when the second noun is the paper-back: now the second noun is the paper.
Instead of examining the paper-back: try turning the paper.
Instead of pulling the fixed in place paper: try taking the paper.
Before taking the paper when the paper is fixed in place:
say "You rip the paper free of the spike.";
now the paper is portable.
Instead of turning or searching or switching on or switching off the paper:
take full time;
set the mirror password;
say "You turn the paper over to look at the notice on the back.[p][tt]Note - the activation process for the scrying mirrors in the library will soon require extra security. In addition to saying '[mirror password]' you now need to show proper identification as well. Other mirrors will be phased in as time permits. - Thraxivar[/tt][p]".
The mirror password is initially "".
To set the mirror password:
if the mirror password is not "", stop; [Only set it once.]
repeat with N running from 1 to 3:
let X be the substituted form of "[a password component]";
now the mirror password is the substituted form of "[mirror password][X]";
To decide what text is a password component:
let N be a random number between 1 and 8;
if N is:
-- 1: decide on "foo";
-- 2: decide on "thu";
-- 3: decide on "zal";
-- 4: decide on "bar";
-- 5: decide on "que";
-- 6: decide on "rax";
-- 7: decide on "ten";
-- 8: decide on "sho";
decide on "ERR".