Scroll Thief — 125 of 138

Section B - Going Up

Every turn when the location is the Chasm and the player is not securely anchored and the player was securely anchored: say "You have a sudden feeling of impending doom."; try looking.

Every turn when the location is the Chasm and the player is securely anchored and the player was not securely anchored: say "You are swung around sharply as the rope slows your descent."; try looking.

Instead of throwing something at from the Chasm to the Overlook:

take full time;

say "You throw [the noun] upwards as hard as you can, but it arcs back and falls past you into the pit.";

if the noun is tied up or the noun is a rope:

say "You manage to catch the rope and pull it back.";

otherwise:

remove the noun from play.

Instead of going in the Chasm:

if the player is flying, make no decision;

if the player is securely anchored:

if the noun is up:

try pulling a random rope tied to the player instead;

otherwise if the noun is down:

say "You're at the end of your rope." instead;

otherwise:

say "You don't have much range of motion at the moment." instead;

otherwise: [The player is falling.]

if the noun is down:

say "You have little choice.";

otherwise:

say "Down seems more likely.".

Instead of going down in the Chasm when the player is flying:

say "You drift downward slightly at a controlled pace."

Reset for izyuk when the location of the currently reset object is the chasm:

if the player can see the currently reset object, say "Gravity takes hold of [the currently reset object] once again."

After casting blorb at something when the location is the Chasm and the location of the strongbox is the Chasm:

say "For a moment the strongbox seems to hover in midair. Then gravity takes hold, and it plummets out of sight into the pit.";

remove the strongbox from play;

make no decision.

The falling timer is initially zero.

Every turn when the player is in the Chasm and the player is not securely anchored and the player is not flying (this is the falling into the chasm rule):

increment the falling timer;

remove the inset mirror from play;

if the falling timer is 5:

say "Suddenly you can see the stone at the bottom of the chasm below you. You barely have time to register that fact before it collides with your body. The results are, of course, fatal.";

record "Falling into a chasm" as an ending;

end the story saying "You have died".

After casting izyuk at the player when the inset mirror is off-stage:

say "You drift back up to the mirror.";

move the inset mirror to the Chasm;

continue the action.

After going when the falling timer is greater than zero:

now the falling timer is zero;

move the inset mirror to the Chasm;

continue the action.

After an actor dropping something when the location of the actor is the Chasm:

if the noun is securely anchored, continue the action;

if the noun is tied to the actor, continue the action;

if the noun is tied to something enclosed by the actor, continue the action;

if the player can see the noun, say "[The noun] [fall], dwindling away below [you or the actor], never to be seen again.";

remove the noun from play.