Scroll Thief — 52 of 138

Chapter 2 - Books and Scrolls

Section A - Scrolls

A spell scroll is a kind of thing. Understand "spell scroll" or "scroll" as a spell scroll. A spell scroll has a spell called the inscribed spell. Understand the inscribed spell property as describing a spell scroll. [This allows us to type READ BOZBAR or GNUSTO BOZBAR, instead of using the name of the scroll.] A spell scroll is usually light.

To say (xyzzy - a spell) in capitals: [These say phrases are workarounds for the way Inform handles nested values in text--you can't look up a property of a property within a simple text substitution.]

let T be "[xyzzy]";

say "[T in upper case]".

To say (X - text) spaced out: [1]

let T be " [X]";

replace the regular expression "(\w)" in T with "\1 ";

say T.

To say (xyzzy - a spell) spaced out:

say "[xyzzy]" spaced out.

To say (xyzzy - a spell) by mode:

if accessibility mode is active and xyzzy is unshortened, say xyzzy spaced out;

otherwise say xyzzy.

Shortening is an action out of world applying to one spell. Understand "shorten [spell]" as shortening.

Check shortening when accessibility mode is inactive: say "Shortening spell names has no effect when accessibility is turned off." instead.

Carry out shortening: now the short-presentation of the spell understood is true.

Report shortening: say "The word [spell understood spaced out] will now be pronounced as [spell understood]. Say 'unshorten [spell understood]' to reverse this."

Unshortening is an action out of world applying to one spell. Understand "unshorten [spell]" as unshortening.

Check unshortening when accessibility mode is inactive: say "Unshortening spell names has no effect when accessibility is turned off." instead.

Carry out unshortening: now the short-presentation of the spell understood is false.

Report unshortening: say "The word [spell understood] will now be pronounced as [spell understood spaced out]."

To say usage of (page - a spell scroll):

let xyzzy be the inscribed spell of the page;

say the explanation of xyzzy.

Definition: a spell scroll (called the page) is powerful:

let xyzzy be the inscribed spell of the page;

if the potency of xyzzy is learnable, no;

yes.

Definition: a spell scroll (called the page) is somewhat powerful:

let xyzzy be the inscribed spell of the page;

if the potency of xyzzy is semilearnable, yes;

no.

Definition: a spell scroll (called the page) is overpowered:

let xyzzy be the inscribed spell of the page;

if the potency of xyzzy is unlearnable, yes;

no.

The description of a spell scroll is "[scroll-description for the item described][r]".

To say scroll-description for (page - a spell scroll):

if the page is blank:

say "The scroll has nothing written on it.";

otherwise:

say "The scroll reads '[inscribed spell of the page by mode]: [usage of the page]'[if the page is powerful]. The spell seems very long and extremely complicated[end if].".

A spell scroll can be read or unread. A spell scroll is usually unread.

After examining an unread spell scroll: now the noun is read; continue the action.

After examining a spell scroll when accessibility mode is active for the first time: say "[note]Note: the magic words are pronounced letter by letter to show their spelling, but you should type them in as complete words: rezrov instead of r e z r o v. You can turn this off for individual spells with the command 'shorten rezrov'.[/note][p]"; continue the action.

After printing the name of a read spell scroll while taking inventory, say " [if blank](blank)[otherwise](bearing the [inscribed spell by mode] spell)[end if]".

[Definition: a spell scroll (called the page) is powerful if the inscribed spell of the page is unlearnable.

Definition: a spell scroll (called the page) is somewhat powerful if the inscribed spell of the page is semilearnable.]

Definition: a spell scroll (called the page) is blank rather than non-blank if the inscribed spell of the page is the null-spell.

Understand "unroll [a spell scroll]" as opening. Understand "roll up/-- [a spell scroll]" or "reroll [a spell scroll]" or "fold [a spell scroll]" as closing. Instead of opening or turning or closing a spell scroll: say "Spell scrolls unroll automatically when you hold them in your hand, and close tightly when you set them down. Nobody is really sure why, but it seems to be a strange side effect of the [b]Presence[/b] in the vellum."

Instead of attacking a spell scroll:

take full time;

say "[The noun] flares with sparkling light as the paper tears, the uncontained [b]Presence[/b] burning the remains to dust.";

remove the noun from play.

Instead of eating a spell scroll: say "According to the Frobozz Magic Magic Supply Company advertisements, they're currently working to perfect an 'edible spell scroll'. But [the noun] [do] not seem to be one of these."