Scroll Thief — 54 of 138

Section B - Spellbooks

A book is a kind of thing.

A spell book is a kind of book. [Defining this as a "kind" makes it easier to have multiple spellbooks in the future, if that were ever required.][1]

Instead of examining a damaged book: say "[The noun] [have] been torn apart and [their] words are no longer legible." instead.

After examining a spell book (called the tome):

if nothing is inscribed in the tome, make no decision;

[ say "[The noun] contains the following spells:[line break]"; ]

repeat with xyzzy running through spells inscribed in the noun:

say " ";

if accessibility mode is active:

say xyzzy spaced out;

otherwise:

if xyzzy is uncast:

say "[b][xyzzy in capitals][/b]";

otherwise:

say xyzzy in capitals;

say ": [explanation of xyzzy][line break]".

Instead of attacking a book (this is the paper is fragile rule):

take full time;

say "You tear into [the noun] furiously, ripping out pages and clawing at the binding. Soon [they] [are] damaged beyond readability.";

now the noun is damaged.

Inscription relates various spells to various spell books. The verb to be inscribed in implies the inscription relation. The verb to bear (he bears, they bear, he bore, he is bearing) implies the reversed inscription relation.

[Understand "[spell]" as a spell book when the spell understood is inscribed in the item described.] [For some reason this doesn't work???]

Should the game choose doing something with a spell scroll when considering some spell books: it is a good choice.

To add (xyzzy - a spell) to (tome - a spell book):

now xyzzy is inscribed in the tome.

The player's preferred spell book is an object that varies. When play begins: now the player's preferred spell book is a random spell book enclosed by the player. [This is an easy way to refer to the player's spell book, allowing it to change during play.]

Definition: a spell book is preferred rather than non-preferred if it is the player's preferred spell book.

After taking a non-preferred spell book for the first time:[2]

say "Taken.[p]Even though it's not yours, you expect you could memorize and cast spells from [the noun] or another spell book without much difficulty."

Instead of opening or closing a spell book: say "Thanks to its magical properties, the spell book is always open to the right place at the right time, but it is also always closed. This innovation eliminates tedious page turning and hunting for spells in tight situations. Many wizardly lives have been saved by this small advance in magical technology."