Scroll Thief — 75 of 138

Chapter 2 - The Library Antechamber and the GNUSTO Scroll

Spells-puzzle is a puzzling scene with puzzle description "acquiring [spell countdown] more spell[s] and escaping". The spells-puzzle begins when the advanced-spells-puzzle ends. The spells-puzzle ends when the player's capture begins.

To decide what number is the spell countdown:

let the count be twelve;

decrease the count by the number of cast learnable spells;

decrease the count by the number of cast semilearnable spells;

if the count is less than one, let the count be one; [In case something goes off the rails]

decide on the count.

The Library Antechamber is a room in the Library. "[if we need a full antechamber description]You've visited the library many times, and this room has never failed to impress you. Sunlight shone in through the circular window in the great domed ceiling, reflecting off the mosaic floor and filling the area with patterns of red and gold. The din of innumerable Enchanters and students made it feel alive.[p]Now, however, it is [dark description] and silent. [Light description][else]You are back in the domed Antechamber of the library[end if][first time].[p]If you remember correctly, the basic spell collection is to the east, and the main stacks to the west. Those are the most likely places to find spell books[only]."

To decide whether we need a full antechamber description:

if the antechamber is unvisited, yes; [If we've never been here before]

if the player was enclosed by the Antechamber, yes; [If we typed LOOK]

no. [If we just arrived by a going action]

To say light description: say "A few shafts of [if it is nighttime]moonlight give everything an ethereal silvery glow[else]light spill in from above".

To say dark description: say "[if it is daytime]empty[else]dark[end if]". [Need nested if-statements here.]

Some shafts of light are insubstantial scenery in the Antechamber. Understand "few" or "moonlight" or "sunlight" as the shafts of light. The description of the shafts of light is "[if it is nighttime]It makes everything seems softer and less real.[else]The mosaic is beginning to sparkle in the light."

Instead of inserting something into the shafts of light:

take full time;

say "[The noun] [shine] in the light[r]";

if the noun is a scrying device and the player can see the mystical relative of the noun:

say ". [The mystical relative of the noun] [glow] with reflected [if it is nighttime]moon[else]sun[end if]light for a moment[r]";

say "."

Instead of doing anything other than examining with the shafts of light: say "It's only light."

[Inverse effect of casting frotz at the shafts of light: say "The light dims for a moment as the spell passes through it, then brightens again."

Instead of casting a spell at the light:

if the spell understood is frotz and the player is reversed, continue the action;

say "You can't really affect the light itself with a spell."]

Instead of an actor going south from the Antechamber while Act 1 is happening:

if the actor is the Adventurer, record the Adventurer's attempt as successful;

if the player cannot see the actor, stop the action; [Prevent it without printing any message.]

if the actor carries a non-blank spell scroll (called the page):

say "A spell book can be reasonably well concealed, but it would be hard to explain how you came by [the page]." instead;

if the security lockdown is happening:

take full time;

say "As [you or the actor] [move] toward the door, a barrier of reddish energy flickers across it. [They] [step] back warily[first time].[p]Okay, new plan: deactivate the alarm somehow, then get the spells and get out. There has to be some way to do that[only]." instead;

if the security lockdown has happened:

unless the actor is the player, say "Nobody's supposed to be in here at the moment. A student being on campus at night isn't too suspicious, but if [the actor] left now, [they] would probably attract attention." instead;

if lleps is inscribed in the player's preferred spell book:

if the Adventurer is in the Clean-Room, say "[The Adventurer] is still in here, and will likely be discovered in the morning. [He] definitely knows enough to implicate you." instead;

say "You pause. There has to be something powerful in the Clean Room to merit all that security, and you'll never get a better chance than this." instead;

say "This is your last chance to join the Circle of Enchanters. With GUE Tech closing you have no hope of a degree. And it's unlikely you could break into the Library again. You need to demonstrate mastery of twelve spells to be considered as an independently-trained Mage, and this is your best chance to acquire them." instead.

The tenets of the Guild are scenery in the Antechamber. Understand "tenet" as the tenets. The description of the tenets is "The first tenet states that Enchanters may never use their talents to aid evil. The second points out that an Enchanter's duty is to the Guild and to the Kingdom, not to the individual. Lesser tenets include rules for conducting votes at meetings, guidelines for passing dishes at Guild banquets, and penalties for revealing the Guild's secret handshake." [Taken from Sorcerer]

The domed ceiling is scenery in the Antechamber. Understand "dome" as the domed ceiling. The description is "An almost-perfect hemisphere of white stone, supported by sixteen columns. The tenets of the Guild of Enchanters are carved around the edge."

The columns are scenery in the Antechamber. Understand "sixteen" or "16" as the columns. The description of the columns is "[one of]You'd never noticed this before, but e[or]E[stopping]ach has a word carved around the top. Let's see...earth, water, air, fire; dark, light, death, life; connectivity, mind, change, time; chaos, order, harmony, balance."

A ropable container called the display case is fixed in place in the antechamber. "Standing in the middle of the floor is a glass display case[if something is in the case], showing off [a list of things in the case][end if]." It is closed, transparent, and not openable. After examining the case: try examining the small brass plaque. The display case is visible between rooms.

Instead of unbolting or opening the display case: say "You don't see any way to open it[--]it's a seamless cube of glass."

Understand "seamless" or "cube" or "glass" or "of glass" as the display case.

An illuminated scroll is a spell scroll in the display case. The inscribed spell of the illuminated scroll is gnusto. The description of the illuminated scroll is "[special gnusto][p]According to the plaque in the display case, this is one of the three original scrolls made of the 'gnusto' spell. The words are surrounded by elaborate decorations picked out in lapis dye and gold leaf." A small brass plaque is part of the display case. It is scenery. The description of the small brass plaque is "'This illuminated manuscript was one of the first three created by the famed magician Berzio in 769 GUE. The [i]gnusto[/i] spell is considered one of the most important discoveries in modern thaumaturgy, as it allows a spell to be cast multiple times without requiring multiple spell scrolls.'"

Instead of an actor taking the illuminated scroll:

say "Another alarm would probably go off if the scroll were removed. And you don't need the scroll itself, just the spell on it. Best to leave it where it is.";

if the actor is the friendly Adventurer, record the Adventurer's attempt as successful.

To say special gnusto:

if accessibility mode is active:

say "Written in flowing and archaic blackletter is the spell G N U S T O : copy an incantation into a book, that it may be repeatedly cast.[r]";

stop;

if Unicode 65319 is supported: [This implies that fullwidth letters are supported.]

say "Ｇｎｕｓｔｏ";

otherwise:

say "Gnusto";

say ": ";

if Unicode 8458 is supported: [This implies that script letters are supported.]

say "ℭopy an ℑncantation into a ℬook, that it may be ℜepeatedly ℭast";

otherwise:

say "copy an Incantation into a Book, that it may be Repeatedly Cast";

say ".[r]".

Should the game choose copying the illuminated scroll to something when comparing spell scrolls: it is a good choice.

Should the game choose casting a spell at the illuminated scroll when comparing spell scrolls: it is a passable choice.

Gnusto-puzzle is a puzzling scene with puzzle description "acquiring the [i]gnusto[/i] spell".

Gnusto-puzzle begins when the illuminated scroll is examined. Gnusto-puzzle ends when the player encloses a spell book which bears gnusto.

Effect of casting vezza at the library antechamber: say "A figure levitating in midair drifts upward toward the window in the ceiling."

Inverse effect of casting vezza at the library antechamber: say "A librarian places the cube of glass on top of the display case, sealing it together with a spell. The tiles in the mosaic swirl in concentric patterns as she does, as though examining this new object."

Empowered effect of casting vezza at the library antechamber: say "A shadowy figure rushes through the library, checking one door after another, finally pausing in front of the storage area to the southeast."