Scroll Thief — 79 of 138

Book II - The Basic Spells

Chapter 1 - The Collection

The Basic Spell Collection is east from the Antechamber. It is dark. "As your eyes adjust, you see that you are in a simple panelled room, dominated by an orange metal box leaning against one wall. The words [tt]FROBOZZ MAGIC SCROLL DISPENSER[/tt] are stencilled across one side in white, and the other is covered with a large sign explaining the proper usage."

The Basic Spell Collection is in the Library.

Basic-spells-puzzle is a puzzling scene with puzzle description "learning the spells from the Basic Spells Collection". The basic-spells-puzzle begins when the Antechamber is visited. The basic-spells-puzzle ends when frotz is inscribed in the player's preferred spell book and blorb is inscribed in the player's preferred spell book and lesoch is inscribed in the player's preferred spell book and nitfol is inscribed in the player's preferred spell book.

When the basic-spells-puzzle ends: say "You smile in satisfaction[--]you now have all four spells from this collection. On to the Main Stacks."

Advanced-spells-puzzle is a puzzling scene with puzzle description "finding some spellbooks in the Main Stacks". The advanced-spells-puzzle begins when the basic-spells-puzzle ends. The advanced-spells-puzzle ends when the bright orange poster is examined or yonk is inscribed in the player's preferred spell book.

A calendar is fixed in place in the Basic Spell Collection. "A calendar on one wall is acting as a strange source of illumination." The description of the calendar is "According to the caption, this is an official Frobozz Magic Flathead Royal Family Calendar. There appear to be [number of filled rows in the Table of Calendar Pages] pages left on it." The calendar is lit. The calendar is affected by frotz. Understand "pages" or "frobozz magic" or "flathead" or "royal" or "family" as the calendar.

Table of Calendar Pages

Understand "tear a/one/-- page from/off of/-- [the calendar]" or "tear [the calendar]" as taking.

Instead of an actor taking the calendar:

take full time;

if the number of filled rows in the Table of Calendar Pages is zero:

if the player can see the actor, say "[The actor] [one of][tear] away the cardboard backing, leaving only the empty frame of the calendar on the wall. The paper disintegrates in [their] hand[or][pull] at the frame, with no effect[stopping].";

otherwise:

repeat through the Table of Calendar Pages:

if the player can see the actor, say "The calendar itself is firmly attached to the wall. [The actor] [tear] away a page, and it disintegrates in [their] hand.[/br][first time] (Shame[--]it would have made a useful light source.)[/br][only] The next one reads '[tt][page entry][/tt]'[p]";

blank out the whole row;

rule succeeds.

Instead of turning the calendar: try taking the noun.

To deactivate the Dispenser: [This shuts off the source of free scrolls after Act 1.]

now the small red light is part of the dispenser;

now the dispenser is inactive.

There is a small red light. It is insubstantial. The description of the red light is "According to the label, this means [tt]PAPER JAM IN TRAY 2 - TECHNICIAN REQUIRED FOR MAINTENANCE[/tt]."

The Frobozz Magic Scroll Dispenser is magical ropable scenery in the Basic Spell Collection. Understand "orange" or "metal" or "box" or "machine" or "machinery" as the dispenser. The description of the dispenser is "A wide orange box, with a row of buttons on the front above a long slot.[p][if active]A large sign attached to the top explains how to properly dispense scrolls[else]A small red light is flashing next to the buttons[end if]."

The dispenser can be active or inactive. The dispenser is active.

Understand "push over/-- [the dispenser] over/--" or "tip over/-- [the dispenser] over/--" as pushing. Instead of pushing or attacking the dispenser, say "That might be hazardous to your health."

The large sign is part of the dispenser. The description of the large sign is "[tt]== FROBOZZ MAGIC ==[br]= SPELL DISPENSER =[br][br]Until the spell catalog is repaired, this device will provide certain basic spell scrolls upon request.[br]Operating Instructions:[br]Press a button to dispense a spell scroll. The Frobozz Magic Spell Dispenser Company, a subsidiary of FrobozzCo International, is not responsible for any injuries resulting...[/br][/tt](blah, blah, blah)".

The row of buttons is part of the dispenser. The description of the row of buttons is "[tt]~FROTZ~ ~BLORB~ ~NITFOL~ ~LESOCH~[/tt]". Instead of pushing the row of buttons: say "You'll need to be more specific. Which button?". The row of buttons is plural-named.

The long slot is part of the dispenser. Instead of inserting something into the long slot: say "The slot is too narrow."

Instead of inserting a spell scroll into the long slot:

take full time;

say "The machine makes an unpleasant grinding sound. The recorded voice says '[tt]Garbage in, garbage out![/tt]' and spews the atomized remains of [the noun] back out at you.";

remove the noun from play.

There is a spell scroll called the newly-printed scroll. The description is "The parchment is smooth[if the inscribed spell of the newly-printed scroll is the null-spell] and unblemished, perfectly blank[else], the lettering dark and mechanically perfect: '[tt][inscribed spell of the newly-printed scroll in capitals]: [usage of the newly-printed scroll][/tt]'[end if]." Understand "parchment" or "square" or "of" or "beautifully" or "printed" or "newly" or "new" as the newly-printed scroll.

A frobozz magic button is a kind of thing. The plural of frobozz magic button is frobozz magic asdfbuttons. [We want "buttons" to redirect to the row object.]

Before pushing a frobozz magic button when the newly-printed scroll is on-stage and the dispenser is active:

say "The Dispenser beeps. '[tt]Only one scroll may be printed at a time. Correcting...[/tt]'[if the player can see the newly-printed scroll] The old scroll crumbles to ashes. [end if]";

remove the newly-printed scroll from play. [This is necessary to keep the scope correct.]

Instead of attacking a frobozz magic button:

say "The machine makes a strange squeaking-clicking sound as you hit the button.";

try pushing the noun.

Instead of touching a frobozz magic button: try pushing the noun.

Should the game choose when comparing the newly-printed scroll against a frobozz magic button: it is a good choice.

Should the game choose when comparing the newly-printed scroll against the scroll dispenser: it is a good choice.

Should the game suggest casting gnusto at a frobozz magic button when testing the second noun: never.

Should the game suggest copying a frobozz magic button to something when testing the noun: never.

Should the game suggest copying something to the scroll dispenser when testing the second noun: never.

[After reading a command when the location is the Basic Spell Collection:[1]

if the player's command includes "gnusto [spell]":

replace the matched text with "gnusto [spell understood] scroll".]

Should the game choose when comparing the blue button against De Evocatio: it is a good choice.

To print a (xyzzy - spell) scroll:

if the dispenser is not magical:

say "Nothing at all happens.";

if the dispenser is inactive:

say "There is an unpleasant grinding noise and nothing happens.";

stop;

say "The Dispenser whirrs, then a beautifully printed square of parchment flies out of the slot at the bottom. You manage to catch it before it touches the ground.";

now the inscribed spell of the newly-printed scroll is xyzzy;

now the newly-printed scroll is unread;

set pronouns from the newly-printed scroll;

fizzle all spells from the newly-printed scroll; [Don't let it remain frotzed.]

move the newly-printed scroll to the player.

The yellow button, the blue button, the green button, and the red button are frobozz magic asdfbuttons. The yellow button, the blue button, the green button, and the red button are part of the row of buttons.

Understand "frotz" as the yellow button. Understand "blorb" as the blue button. Understand "nitfol" as the green button. Understand "lesoch" as the red button.

The description of the yellow button is "[tt]~FROTZ~[/tt]". The description of the blue button is "[tt]~BLORB~[/tt]". The description of the green button is "[tt]~NITFOL~[/tt]". The description of the red button is "[tt]~LESOCH~[/tt]".

Carry out pushing the yellow button:

print a frotz scroll.

Carry out pushing the blue button:

print a blorb scroll.

Carry out pushing the green button:

print a nitfol scroll.

Carry out pushing the red button:

print a lesoch scroll.

Report pushing a frobozz magic button: [say "[The noun] makes a slight clicking sound as you release it.";] rule succeeds.

Light-puzzle is a puzzling scene with puzzle description "finding a light source to explore the dark areas". Light-puzzle begins when in darkness. Light-puzzle ends when the security lockdown begins.

Effect of casting vezza at the Basic Spell Collection: say "The machine whirrs for a moment, then begins to grind, then stops. A little red light begins blinking on the front panel."

Empowered effect of casting vezza at the Basic Spell Collection: say "The dust-covered warning light blinks a few times, then turns off with a sad [i]whirrr[/i]."

Inverse effect of casting vezza at the Basic Spell Collection: say "An IT worker folds a long roll of parchment along its perforations, checks the lines of holes along the edges, then feeds it into the back of the machine."

Effect of casting kulcad at the dispenser:

say "The machine goes silent and its buttons go dark.";

now the dispenser is inactive;

now the dispenser is not magical.