Scroll Thief — 80 of 138

Chapter 2 - The Alarm

The security lockdown is a puzzling scene with puzzle description "deactivating the alarm". The security lockdown begins when the casting count of frotz is greater than zero.

When the security lockdown begins:

say "As the spell is completed, a booming voice suddenly resounds through the library.[p][b]Hello, footpad![/b] [tt]Your after-hours use of a 'frotz' spell within the Library has activated one of the triggers of a Frobozz Magic Alarm Company security system. Please be aware that the authorities have been alerted to your misdeeds, and this building has been placed into extreme security lockdown. All potential exits have been sealed, and additional traps and triggers have been enabled in high-risk areas.[p]If this alarm has been activated in error, please speak today's passphrase.[p]Have a nice day![/tt][p]...okay, this is getting worse. But you won't panic. You will [i]not[/i] panic. You just need to get your spells and get out of here.";

award points for "triggering the alarm".

Every turn when the security lockdown is happening:

say "A pleasant voice speaks from [r]";

let the place be the Disused Closet;

if the alarm box is on-stage, let the place be the location of the alarm box;

if the location is the place:

if the alarm box is fixed in place:

say "a small glass box on the ceiling";

move the alarm box to the Disused Closet;

else if the player encloses the alarm box:

say "the alarm box in your hand";

else if the holder of the alarm box is a container:

say "within [the holder of the alarm box]";

otherwise:

say "the alarm box";

otherwise:

let the way be the best route from the location to the place, using doors;

if the way is a direction:

say "[the way]";

otherwise:

say "somewhere nearby";

say ": '[tt]Extreme security lockdown[/tt]'[p]".

An alarm box is fixed in place. "[if undamaged]A[else]The remains of a[end if] small glass box hang[if undamaged]s[end if] from the ceiling above you." The alarm box can be active or inactive. It is active. It is magical and addressable.

The description of the alarm box is "A delicate box of red and white glass, filled with [if undamaged]whirring [end if]magical components[if damaged]. Its workings have been damaged beyond repair by some unruly vandal[else if the alarm box is fixed in place and hard mode is false], hanging from the ceiling by a thin metal chain[else if the alarm box is fixed in place and hard mode is true], quite firmly attached to the ceiling[end if]." Understand "small" or "glass" or "red" or "white" or "red and white" or "delicate" or "workings" or "whirring" or "components" or "magical components" or "thin" or "chain" as the alarm box.

First before answering the player that a topic in the presence of the alarm box: try answering the alarm box that the topic understood instead. [SAY IPSA SCIENTIA - short-circuit the action because talking to yourself is blocked]

After answering another person that a topic in the presence of the alarm box: try answering the alarm box that the topic understood; make no decision. [MOUSE, IPSA SCIENTIA - allow the other person's action routines to respond, then have the alarm box react too]

Instead of an actor attacking the alarm box when the alarm box is fixed in place and the actor is not flying:

say "The box is unfortunately out of reach."

Instead of an actor throwing something at the alarm box when the alarm box is fixed in place:

take full time;

if the actor is the Adventurer, record the Adventurer's attempt as successful;

record the outcome of the actor dropping the noun silently;

if the action failed, stop the action;

if the actor is affected by fooble or the actor is the Adventurer: [The Adventurer has good aim.]

if the noun is heavy:

if the player can see the actor, say "[regarding the actor][Possessive] aim is true, and with uncannily perfect precision [the noun] [collide] with the alarm box. Its delicate mechanisms explode in a shower of glass.";

now the box is damaged;

otherwise:

if the player can see the actor, say "[The actor] [throw] [the noun] with impressive aim, but [they] [have] no effect on the box.";

otherwise:

if the player can see the actor, say "[regarding the actor][Possessive] aim is off, and [the noun] misses the box by a wide margin.";

Instead of an actor attacking or cutting the alarm box:

take full time;

if the actor is the Adventurer, record the Adventurer's attempt as successful;

if the player can see the actor:

if the alarm box is undamaged:

say "The box shatters under [regarding the actor][possessive] fist, its delicate mechanisms exploding in a shower of glass[if the box is active].[p]Beautiful silence ensues[end if].";

otherwise:

say "[The actor] [pound] the box a bit more.";

now the box is damaged.

Instead of an actor throwing something at the alarm box when the alarm box is portable:

take full time;

if the actor is the Adventurer, record the Adventurer's attempt as successful;

record the outcome of the actor dropping the noun silently;

if the action failed, stop the action;

if the noun is light:

if the player can see the actor, say "[The noun] [bounce] disappointingly off the box.";

stop the action;

if the player can see the actor:

if the box is undamaged:

say "The box shatters under [the noun]'s weight, its delicate mechanisms exploding in a shower of glass[if the box is active].[p]Beautiful silence ensues[end if].";

otherwise:

say "[The noun] [hit] the glass box with a satisfying [i]crunch[/i].";

now the box is damaged.

Instead of an actor putting something on the alarm box: try the actor throwing the noun at the second noun.

Instead of an actor inserting something into the alarm box: try the actor throwing the noun at the second noun.

Effect of casting blorb at the alarm box when the alarm box is fixed in place and hard mode is false:

say "A glowing cube materializes out of the air, carefully enclosing the alarm mechanism. The strongbox seems to float for a moment as the spell concludes. Then gravity takes effect and it swings downward sharply. The thin chain makes a valiant effort to support the additional weight, but the strongbox is too heavy for it, and with a weak [i]snap[/i] it comes crashing down to land at your feet[if the alarm box is active].[p]Unfortunately, the box seems to have also protected the mechanism from the fall. You can still hear the recorded voice speaking faintly through the thick metal[end if].";

now everything in the strongbox is in the holder of the strongbox;

move the alarm box to the strongbox;

now the alarm box is handled;

now the alarm box is portable;

set pronouns from the strongbox;

now the remembered location of the alarm box is the strongbox;

move the strongbox to the disused closet.

Effect of casting serage at the alarm box:

say "You attempt to bring the alarm under your control, but it doesn't really have a mind per se[--]or at least, not one complex enough to take over with [i]serage[/i]."

Effect of casting nitfol at the alarm box:

say "Nothing much happens. The voice is more like a recording than an actual person or animal, and you can understand it perfectly well as it is anyway."

Effect of casting rezrov at the undamaged alarm box:

say "Nothing much happens. It seems it isn't designed to open."

Empowered effect of casting rezrov at the undamaged alarm box:

say "The box strains slightly, then flies open at the seams, tiny glass components spilling out the sides.";

now the alarm box is damaged.

Effect of casting kulcad at the undamaged magical alarm box:

say "The colors fade from the glass and the whirring ceases.";

now the alarm box is inactive;

now the alarm box is not magical;

now the description of the alarm box is "A cube of dull glass, quiet and still."

The current passphrase is initially "ipsa scientia".

To alter the passphrase: [Note: the switch-case style syntax doesn't work with strings, so I need to write it out with else-ifs instead.]

if the current passphrase is "ipsa scientia":

now the current passphrase is "noli metaludare"; ["Don't metagame"]

else if the current passphrase is "noli metaludare":

now the current passphrase is "nonne antequam ludebas"; ["Surely you've played [this] before?"]

else if the current passphrase is "nonne antequam ludebas":

now the current passphrase is "hoc facere desiste"; ["Stop doing this!"]

otherwise:

now the current passphrase is "arius";

repeat with N running from 1 to 5:

let X be the substituted form of "[a password component]";

now the current passphrase is the substituted form of "[X][current passphrase]".

Instead of answering the alarm box that a topic when the current passphrase is the substituted form of "[the topic understood]":

take full time;

if the alarm box is not familiar:

say "You say the phrase. Nothing happens, not that you'd really expected it to.";

alter the passphrase instead; [Metagamers. :P ]

if the alarm box is inactive:

say "The alarm is already deactivated." instead;

if the alarm box is damaged:

say "It wouldn't do much good now." instead;

say "The pleasant voice speaks again. '[tt]Passphrase accepted. Extreme security lockdown mode lifted.[/tt]'";

now the alarm box is inactive.

Instead of conversing when the noun is the alarm box: [TODO: why doesn't this work?]

say "As far as you can tell, the alarm box takes no notice whatsoever.";

take full time.

Instead of answering the alarm box that "the/-- password/passphrase":

if the alarm box is familiar:

say "You know the password now: [i][current passphrase in upper case][/i].";

otherwise:

say "You say '[topic understood]'. Nothing happens.";

take full time.

The security lockdown ends when the alarm box is inactive or the alarm box is damaged.

When the security lockdown ends:

award points for "deactivating the alarm";

mark checkpoint alarm as passed.