Scroll Thief — 84 of 138

Section C - The Scrying Room Itself

The Scrying Room is northwest of the Antechamber. It is dark. "The walls and shelves of this room are lined with mirrors and crystals of all types. Presumably you would have learned to scry in a more advanced Thaumaturgy class, but it wasn't covered in the first or second year of studies[first time].[p]Almost all of them are deactivated for the night, but if you searched you might find some that had been left on[only]."

The Scrying Room is in the Library.

After examining the wall-sized mirror when the security lockdown is not happening:

display the boxed quotation

"And moving thro' a mirror clear

That hangs before her all the year,

Shadows of the world appear.

-- The Lady of Shalott, Alfred Lord Tennyson";

continue the action.

The scrying repository is a container. [Objects here are moved to the scrying room once the player has seen them.]

There is a thing called some mirrors and crystals. It is plural-named and scenery. It is in the scrying room. Understand "shelves" as the mirrors. The description of the mirrors is "They come in all different shapes and sizes: [a list of inactive scrying mirrors in the Scrying Room] catch your eye. [if there is an active scrying device in the Scrying Room]Most are dark and foggy, but you notice [a list of active scrying devices in the Scrying Room] glowing with inner light[otherwise]All of them are dark and clouded[end if][if the unhandled aquarium is in the scrying room].[p]Strangely enough, there also appears to be a glass aquarium on one of the shelves. It looks rather out of place with no water in it[end if]."

Instead of searching the mirrors: try examining the mirrors.

Should the game choose examining the unexamined mirrors: it is a good choice.

Should the game choose searching the unexamined mirrors: it is a good choice.

Instead of taking the mirrors and crystals: say "There must be hundreds of them here. You'll need to be more specific about which one you want."

Understand "mirror" or "sphere" or "aquarium" or "palantir" as the mirrors when the mirrors are unexamined.

Before examining the mirrors:

repeat with the item running through things in the scrying repository:

move the item to the scrying room.

[Rule for deciding whether all includes an unhandled thing when the location is the Scrying Room: it does not. [Prevent GET ALL]]

Rule for deciding whether all includes the mirrors: it does.

A wall-sized mirror is a scrying mirror in the scrying repository. Understand "wall" or "sized" as the wall-sized mirror. A gilt mirror is a scrying mirror in the scrying repository. Understand "gilded" as the gilt mirror. A stained mirror is a scrying mirror in the scrying repository.

Instead of answering an undamaged scrying mirror that a topic:

take full time;

let T be the substituted form of "[topic understood]";

if T is the mirror password:

if the noun is active:

say "[The noun] [shimmer] briefly." instead;

let the activation state be false;

if the noun is:

-- the inset mirror: [No further conditions.]

let the activation state be true;

award points for "activating a hidden mirror";

-- the gilt mirror:

[if the player is wearing something...etc...otherwise...]

say "Words appear briefly on the surface of the glass. [i]As per the new two-factor security policy, you must be wearing the identifiable article of clothing assigned to you by Infrastructural Thaumaturgy to activate this mirror.[/br][/i][p]";

-- the stained mirror:

say "Words begin to appear on the surface of the glass, but they are twisted and distorted, flickering slightly in the dim light. [if accessibility mode is active]The letters are almost recognizable but they shimmer and dim before you can make them out.[r][else][i]∀s p3r the ueM tM0-tM0-tM0-tMMM-≃⋊ ωεαριγγ θε ιδεντιφιabλeeeĦœ ᴒᵹᴥ♅♓♓♓...[/i][end if] Then it goes dark again.";

if the activation state is true:

say "As you say the word '[topic understood]', there is a flash of light and the surface of the mirror ripples and distorts for a moment.";

activate the noun;

otherwise:

say "You say '[topic understood]', but nothing happens."

A small blue sphere and a small red sphere are palantiri in the scrying repository. The blue sphere is mystically linked to the red sphere.

The glass aquarium is a ropable transparent closed container in the scrying repository. ["For some reason, a small glass aquarium is sitting on one of the shelves. It looks very out of place with no water in it."] It is not openable. The small transparent sphere is a palantir in the aquarium. Understand "crystal" or "box" as the aquarium. The description of the aquarium is "A solid cube of glass[if hard mode is true], reinforced with metal bands[else if the aquarium is open], covered in thin cracks. One of the faces has been neatly removed[end if]." Understand "reinforced" or "metal" or "bands" as the aquarium when hard mode is true.

Effect of casting rezrov at the aquarium: say "You complete the spell, but the aquarium refuses to open. It appears to be a solid cube of crystal[if the shattered display case is solved] (which is clearly stronger than the display case in the Antechamber)[end if], and the rezrov spell isn't powerful enough to force it open."

Empowered effect of casting rezrov at the aquarium:

if hard mode is true:

say "The aquarium strains, beginning to open, but the metal bands around it keep the glass from breaking.";

otherwise:

say "Cracks spread across the aquarium, and one face shatters into thousands of tiny slivers of crystal! You cover your eyes for a moment, and when you look at the aquarium again, it does indeed seem to be open.";

now the aquarium is damaged;

now the aquarium is open.

After casting krebf at the damaged aquarium: now the aquarium is closed; continue the action.

Unsuccessful attempt by the Adventurer attacking the aquarium:

say "[The Adventurer] motions for you to stand back, then picks up the aquarium and tosses it with effort towards the ceiling. It comes down with a massive [b]crash[/b], but doesn't even seem scratched. [He] scowls at it.".

Instead of attacking the aquarium:

say "The crystal makes a slight [i]bong[/i] sound, but nothing else happens.";

take full time.

Report throwing something at the aquarium:

say "[The noun] has no effect on the surprisingly resilient crystal."

Effect of casting a spell at something when the second noun is enclosed by the aquarium:

say "The casting goes awry[--]something about the crystal of the aquarium is interfering."

Effect of casting kulcad at the aquarium:

say "The glass shimmers for a moment. Then it seems to thin out, stretching like a soap bubble, until with a delicate, crystalline sound it disintegrates into slivers.";

repeat with the item running through things in the aquarium:

move the item to the holder of the aquarium;

remove the aquarium from play.

When play begins: activate the wall-sized mirror. [This one is active from the start, as you need the Adventurer to get the later ones.]

A glass cabinet is a container in the Scrying Room. It is closed, locked, transparent, fixed in place, and openable. "[if De Evocatio is in the cabinet]A glass cabinet on one of the shelves contains a blue-and-silver book, titled [De Evocatio]. Books kept in these rooms tend to contain spells relevant to the equipment there, so presumably it contains spells for scrying.[otherwise][run paragraph on][end if]". The description of the cabinet is "A simple cabinet with a tiny metal lock on one side.". Understand "case" as the cabinet. [Some people automatically call it a 'case' after the gnusto puzzle.] Understand "tiny" or "metal" or "lock" as the cabinet.

The silver key unlocks the glass cabinet.

De Evocatio is an unfamiliar spell book in the glass cabinet. The description of De Evocatio is "This is a nice spell book, bound in blue cloth with silver stitching on the cover and spine. [if De Evocatio is unfamiliar]The title may have something to do with scrying, although you aren't quite sure[otherwise]The title (almost) means 'On Evocation' or 'On Summoning'[end if]. It contains the following spells:[run paragraph on]". The printed name is "[i]De Evocatio[/i]". [It should really be De Evocatione or De Evocationibus, but those sound awkward in English. My explanation is that a scribe (i.e. me when I was first coding this) didn't realize that it was third declension and thought the word was "evocatius, -i".]

[The 'familiar' property changes the description slightly when the player asks someone about the name.]

Understand "blue" or "silver" or "blue-and-silver" or "titled" as De Evocatio.

Understand "book" as De Evocatio when De Evocatio is unexamined.

Should the game choose when comparing the blue sphere against De Evocatio and the blue sphere is examined: it is a good choice.

Instead of attacking the glass cabinet: say "You strike the glass with your hand. It makes a dull [i]thud[/i] but refuses to break."; take full time.

Instead of throwing something at the glass cabinet: try attacking the cabinet.

Cabinet-puzzle is a puzzling scene with puzzle description "opening the locked cabinet in the Scrying Room". The cabinet-puzzle begins when the glass cabinet is known. The cabinet-puzzle ends when the glass cabinet is open.

Zifmia is inscribed in De Evocatio. Vezza is inscribed in De Evocatio. [It seems someone else made the same mistake as the player and gnusto'd a scrying spell into the summoning book.]

Understand "zifmia" or "vezza" as De Evocatio when the command is not metamagic. [Give a better response to GNUSTO ZIFMIA.]

Effect of casting vezza at the Scrying Room when the Adventurer is neutral: say "A figure faces a single glowing mirror, casting a spell of some sort. Suddenly a bedraggled [if the adventurer is female]wo[end if]man appears out of nowhere and cowers in fear before [regarding the player standin][them]."

Effect of casting vezza at the Scrying Room: say "Several mirrors shine with light, reflecting tiny scenes into the room."

Empowered effect of casting vezza at the Scrying Room: say "The stained mirror suddenly flickers to life, and a figure seems to walk through it and disappear."

Inverse effect of casting vezza at the Scrying Room: say "A robed librarian walks around to each mirror and makes some sort of gesture. As she leaves, all of the glasses go dark. Then the wall-sized mirror begins to glow again of its own accord."