Section B - The Kulcad Box
Kulcad-puzzle is a puzzling scene with puzzle description "opening the ornate box". Kulcad-puzzle begins when the ornate box is handled. Kulcad-puzzle ends when the ornate box is open.
The ornate mahogany box is a magical container in the drawer. It is locked, not lockable, closed, opaque, and openable.
Effect of casting rezrov at the ornate box:
say "The words shift: 'Nice try.'"
Empowered effect of casting rezrov at the ornate box:
say "The words shift: 'Very nice try.'"
Inverse effect of casting rezrov at the ornate box:
say "The words shift: '.yrt eciN'".
The description of the ornate box is "It's about one foot by three inches by three inches, just the right size to contain a spell scroll. Three [if the ornate box is magical]metal[else]painted wood[end if] pillars jut out from one of the long sides: one lead, one silver, and one gold. There [is-are a list of things on the lead pillar] on the lead pillar, [a list of things on the silver pillar] on the silver one, and [a list of things on the gold pillar] on the gold. Tiny words, [if the ornate box is magical]inlaid with[else]painted like[end if] copper, run along the edge: 'move the discs from lead to gold'[first time][p]You have seen puzzles of this type before. A box secured with a stupid puzzle lock like this won't contain anything essential[--]anyone who found it could open it if they had the inclination[only]."
A Hanoi pillar is a kind of supporter.
The gold pillar is a Hanoi pillar. It is part of the ornate box.
The silver pillar is a Hanoi pillar. It is part of the ornate box.
The lead pillar is a Hanoi pillar. It is part of the ornate box.
A Hanoi disc is a kind of thing.
A large ebony disc, a medium maplewood disc, a small canary-wood disc, and a tiny ivory disc are Hanoi discs on the lead pillar. Understand "maple" as the maplewood disc. Understand "canary" as the canary-wood disc.
Definition: a Hanoi disc is pillared rather than unpillared if it is on a Hanoi pillar.
Instead of putting something which is not a hanoi disc on a hanoi pillar:
say "[The second noun] is too small for anything except the four discs to fit on it."
Instead of inserting a hanoi disc into a hanoi pillar, try putting the noun on the second noun.
To decide whether the rules are being enforced: decide on whether or not the mahogany box is magical.
Emptying a hanoi pillar is breaking the rules. Transferring a hanoi pillar into something is breaking the rules. Dumping a hanoi pillar onto something is breaking the rules. [Giving a hanoi disc to someone is breaking the rules. Taking a hanoi disc when the player encloses a hanoi disc is breaking the rules. Dropping a hanoi disc is breaking the rules. Inserting a hanoi disc into something which is not a hanoi pillar is breaking the rules. Putting a hanoi disc on something which is not a hanoi pillar is breaking the rules.]
[Taking a hanoi disc when the number of pillared hanoi discs is less than four is breaking the rules.]
Instead of breaking the rules when the rules are being enforced:
say "Words appear on the side of the mahogany box: 'You may only move one disc at a time.'";
take full time.
Instead of taking a pillared hanoi disc when the number of pillared hanoi discs is less than four and the rules are being enforced:
say "Words appear on the side of the mahogany box: 'You may not take another disc until [the random unpillared hanoi disc] is back on a pillar.'";
take full time.
Instead of taking a hanoi disc when the player encloses the ornate box:
say "It would be hard to manipulate [the noun] while you're carrying the box. You should set it down somewhere first."
To decide whether (X - a hanoi disc) is larger than (Y - a hanoi disc):
if X is Y, no; [I don't know why this would happen, but it should be handled.]
if X is the ebony disc, yes;
if X is the maplewood disc and Y is not the ebony disc, yes;
if X is the canary-wood disc and Y is the ivory disc, yes;
if X is the ivory disc, no;
no. [This should never happen.]
Test hanoi with "x box" holding the ornate box.
Check putting a hanoi disc on a hanoi pillar when the rules are being enforced:
repeat with the piece running through hanoi discs on the second noun:
if the noun is larger than the piece:
say "The words shift: '[The noun] is larger than [the piece]!'";
stop the action;
make no decision.
Check taking a hanoi disc when the noun is on a hanoi pillar:
let the stick be the holder of the noun;
repeat with the item running through hanoi discs on the stick:
if the item is not the noun and the noun is larger than the item:
say "You can't remove [the noun] from [the stick] when [the item] is above it.";
stop the action;
make no decision.
Instead of putting a hanoi disc on a hanoi disc when the second noun is on a hanoi pillar:
say "(on [the holder of the second noun], on top of [the second noun])[ccb]";
try putting the noun on the holder of the second noun.
After putting a hanoi disc on a hanoi pillar when the rules are being enforced:
if the number of hanoi discs on the gold pillar is four:
say "As you drop the ivory disc into place, you hear a click from inside the box.";
now the ornate box is unlocked;
award the "Ivory Tower" achievement;
otherwise if the number of hanoi discs on the lead pillar is four:
say "You hear a series of clicking sounds as the box seals itself again.";
now the ornate box is closed;
now the ornate box is locked;
otherwise:
make no decision.
The ornate box contains a spell scroll called the brittle scroll. The inscribed spell of the brittle scroll is kulcad.
Instead of inserting something which is not a spell scroll into the open ornate box:
say "The box is only designed to hold spell scrolls."
Effect of casting kulcad at the magical ornate box:
say "The shine fades from the columns, leaving only dull painted wood.";
now the ornate box is not magical.