Scroll Thief — 97 of 138

Chapter 3 - The Stacks

Section A - The First Room

The Main Stacks is a dark room in the Library. It is north of the Returns Room, south of the Scrying Room, and west of the Antechamber. "Compared to the vast Antechamber, this room is less impressive than you had envisioned. The east end is a high open archway flanked by smaller doors to the north and south. But the floor, walls, and ceiling slant sharply inward from there; the west wall is a pitch-black square barely five feet on a side."

[Understand "read every/all of/-- the/-- book/books" as a mistake ("No doubt it would be enlightening, but you don't have a lifetime to spare right now.") when the location is the Main Stacks.]

There is a room called Among the Shelves. [Needed here for door definitions - filled in below]

The front desk is an enterable supporter in the Main Stacks. "[if the bright orange poster is unhandled]Strangely-colored shadows fill the room; [a bright orange poster] has been placed over [the crystal] on the front desk[else if the decorative crystal is lit][A decorative crystal] on the front desk fills the room with a warm golden glow[else]The front desk stands in front of the west wall[end if]."

A decorative crystal is fixed in place on the front desk. It is lit and affected by frotz. The description of the crystal is "A sort of faceted sphere carved out of glass[if the crystal is lit]. A warm light shines through it[end if]." Understand "faceted" or "sphere" or "glass" as the crystal.

The description of the front desk is "This is where the librarians would sit to watch over the stacks. The front is polished and smooth, while the back opens into a wide compartment."

[The row of lockers is part of the front desk. Before doing anything except examining with the row of lockers: say "You'll need to be more specific, there are ten of them." The description of the row is "Numbered from one to ten, with a small lock on each."]

A locker is a magical container in the Main Stacks. It is closed, openable, locked, and fixed in place. "A locker for students['] belongings squats in one corner." The description of the locker is "Students would leave their spellbooks and such in here before entering the stacks, to deter theft. It is currently [if the locker is locked]closed and locked[--]maybe something was left overnight?[else if the locker is closed]closed.[else]open.[end if][p]An engraving on top says [tt]Frobozz High-Security Locker: closes automatically in presence of potential burglars[/tt]." Understand "engraving" or "security" or "high security" or "high-security" or "frobozz" as the locker.

Every turn when (the location is the Main Stacks or the location of the Adventurer is the Main Stacks) and the locker is open and the locker is magical:

if the locker is visible, say "The locker clicks shut. 'Unauthorized.'";

now the locker is closed.

Effect of casting kulcad at the magical locker:

say "With a [i]click[/i] the hinges seem to loosen slightly, and no longer tense up at your approach.";

now the locker is not magical.

A translucent scroll is a spell scroll in the locker. The inscribed spell of the translucent scroll is vhelas. The description of the translucent scroll is "The paper is very old and worn, and may have been torn out of a book.[p][scroll-description for the translucent scroll]". Understand "old" or "worn" as the translucent scroll.

The back compartment is a closed locked container. It is part of the front desk.

Before casting rezrov at the front desk: try casting rezrov at the back compartment instead.

Instead of inserting something into the front desk:

if the front desk is locked:

say "(putting [regarding the noun][them] on top)[ccb]";

try putting the noun on the front desk;

otherwise:

say "(into the back compartment)[ccb]";

try inserting the noun into the back compartment.

The black square is a magical scenery door, west of the Main Stacks and east of the Shelves. The description of the square is "It seems [if the square is magical]blacker than should be possible[else]exactly the color it should be[end if]." It is closed and locked.

Effect of casting frotz at the magical black square: say "It flickers for a moment, then returns to its normal color."

Inverse effect of casting frotz at the magical black square: say "Not much happens, at least not that you can see."

Inverse effect of casting frotz at the nonmagical black square: say "Nothing obvious happens. There must have been more to the spell than that."

Empowered effect of casting frotz at the magical locked black square:

say "Ripples of light shine through the darkness for a moment. Then they cross in the center and spread outward like an iris, revealing a black wooden door behind the darkness.";

now the square is not magical.

Effect of casting rezrov at the magical black square: say "It's difficult to aim your spell right, and something goes awry. There's no easy way to focus unlocking into empty darkness.".

Effect of casting kulcad at the magical black square:

say "The darkness dissolves, leaving plain wood in its place.";

now the black square is nonmagical.

Effect of casting kulcad at the nonmagical black square:

say "Nothing much happens. The door is just plain wood now; the magic was in the darkness."

Instead of unlocking or opening the magical black square:

say "It does seem like a door, but there's no obvious way to open it. Just...darkness."

[Effect of casting vezza at the Main Stacks: say "A figure walks through the stacks, and the books and doors shift around [regarding the player standin][them][first time]. Huh, you'd never seen that from a fixed viewpoint before, but the entire room seems to rearrange itself to give the impression of standing in one place[only]."]

Effect of casting vezza at the Main Stacks: say "A figure steps through the darkness to the west, disappearing from sight."

Empowered effect of casting vezza at the Main Stacks: say "A number of spellbooks flutter through the south door like birds released from a cage. With a great flapping and rustling of pages they swoop into the darkness and return to their proper places on the shelves."

Inverse effect of casting vezza at the Main Stacks: say "A blue-robed IT worker drapes the poster over the desk, then wheels another cart filled with books away to the south."

On the front desk is a bright orange poster. Understand "notice" as the orange poster.

The description of the orange poster is "[tt]~~~ NOTICE ~~~[p]The recent magical disturbances have caused problems with the automatic spell-lookup catalog. We have found a solution for this problem, but in the meantime all catalogs and all spellbooks in the Main Stacks are temporarily unavailable. All other books should be accessible during this time. We apologize for the inconvenience[br] - Infrastructural Thaumaturgy[/tt][p][first time]What? You hadn't heard of any IT work happening tonight...[only]".

Instead of turning or pushing or pulling the unhandled orange poster:

say "You push the poster off to one side, and the light becomes much brighter.";

now the poster is handled.

The Encyclopedia Frobozzica is fixed in place in the Main Stacks. "Sitting on a wooden podium near one wall is one volume of the [i]Encyclopedia Frobozzica[/i].". Understand "podium" or "wooden" or "volume" or "volume of the" as the Encyclopedia. The description of the Encyclopedia is "The volume here is titled 'Magical Spells and Effects'. It's about 24 inches tall, 18 inches wide, and 12 inches thick. You flip to an entry at random: [no line break][random encyclopedia entry]".

A small label is part of the Encyclopedia. After examining the Encyclopedia: say "You notice a small label attached to one side." The description of the label is "[tt]COMING SOON: the SOLID GOLD**** Deluxe Edition of this volume will contain full information on the incantations and gestures required to cast the spells, allowing them to be copied out onto scrolls at any time! Only zm10,000* from the Frobozz Magic Encyclopedia Company, a subsidiary of FrobozzCo Incorporated.[p]* Plus tax**.[p]** Plus shipping, handling, and installation*** fees.[p]*** On-site installation by FrobozzCo technicians required. Physical size 8.25 x 8.25 x 6.75 feet. Allow up to three years for delivery.[p]**** Not actually made of solid gold.[/tt]"

Instead of consulting the Encyclopedia about a topic listed in the Table of Encyclopedia Entries: say "[tt][topic understood]: [response entry][/tt][p]"; take full time.

Instead of consulting the Encyclopedia about a topic:

take full time;

say "You don't see any spell by that name listed here."

Instead of consulting the Encyclopedia about "[spell]":

take full time;

let xyzzy be the spell understood;

say the encyclopedia entry for xyzzy.

Understand "turn a/the/one/-- page" as a mistake ("You glance quickly at another of the entries: [random encyclopedia entry]") when the player is in the Main Stacks [and the library travel distance is zero].

After examining the encyclopedia for the first time:

suggest the command "LOOK UP (X) IN ENCYCLOPEDIA";

continue the action.

To say a/-- random encyclopedia entry:

say line break;

if a random chance of 1 in 5 succeeds:

choose a random row from the Table of Encyclopedia Entries;

say "[tt][name entry spaced out]: [response entry][/tt][/br][p]";

otherwise:

let xyzzy be a random spell;

say the encyclopedia entry for xyzzy.

To say the/-- encyclopedia entry for (xyzzy - a spell):

if xyzzy is blorple, say "There is an entry, but the text is blurred and illegible. Strange.";

otherwise say "[tt][xyzzy by mode][if xyzzy is semilearnable or xyzzy is unlearnable]*[end if]: [explanation of xyzzy][if xyzzy is semilearnable or xyzzy is unlearnable][p]*note: too powerful for gnusto[end if][/tt][no line break][p]".

Table of Encyclopedia Entries

A small shelf is fixed in place in the back compartment. It is a supporter.

Instead of examining the shelf when a library book is on the shelf:

take full time;

let the tome be a random library book on the shelf;

say "Your eyes wander over the shelf, picking out [tome].[line break][run paragraph on]".

Rule for printing the name of the small shelf when not inserting or removing and the number of library books on the shelf is greater than one:

say "shelf of library books";

omit contents in listing.

Instead of inserting something into the shelf: try putting the noun on the shelf.

A library book is a kind of book. Some library books on the shelf are defined by the Table of Readable Library Books.

Rule for printing the name of a library book: say "[i][printed name][/i] by [author]". A library book is always proper-named.

Instead of consulting a library book about a topic: say "The book doesn't seem to have an index, so there's no easy way of looking up a specific topic."

Before listing contents [when taking inventory]: group library books together as "library books".

Table of Readable Library Books

The printed name of The Enchanter Never Rings Twice is "The Enchanter Never Rings Twice: 101 Uses for Rezrov". [This fixes the colon.] Understand "uses" or "uses for rezrov" or "101 uses for rezrov" as The Enchanter Never Rings Twice.

After reading a command when the location of The Enchanter Never Rings Twice is the location: if the player's command includes "101", replace the matched text with "uses". [HACK]

The printed name of A Brief History of Magic is "A Brief History of Magic". [This fixes the indefinite article.]

Understand "return [a book]" or "reshelve [a book]" as a mistake ("The reshelving device is deactivated for the night. Just put it back in the Library and it will eventually find its proper position.").