Scroll Thief — 30 of 138

Section B - Untying

Understand "untie [things] from [something]" or "untie [something] from [things]" as untying it from. Understand "untie [things]" as untying it from.

Rule for supplying a missing second noun while untying something from (this is the find the rope to untie rule):

if the number of secondary things tied to the noun is 0, say "[The noun] is already entirely free." instead;

if the noun is a rope:

if the number of touchable nonrope things which are tied to the noun > 1:

say "You'll have to say which thing you want to untie [the noun] from.";

rule fails;

otherwise:

if the number of touchable nonrope things tied to the noun is 0, say "[We] can't reach [the random nonrope thing tied to the noun]." instead;

let the anchor be a random touchable nonrope thing which is tied to the noun;

say "(from [the anchor])[ccb]";

now the second noun is the anchor;

otherwise:

if the noun is tied to a rope (called the tied object):

say "(from [the tied object])[ccb]";

now the second noun is the tied object.

Untying it from is an action applying to two things.

Should the game suggest untying something from something when the noun is not tied to the second noun: it is a bad suggestion.

Before untying a rope from something (this is the untie rope from something rule): try untying the second noun from the noun instead.

Before untying something from a rope (this is the take before untying rule):

if the second noun is not held:

carry out the implicitly taking activity with the second noun.

Check untying it from (this is the check if tied before untying rule):

unless the noun is tied to the second noun or the second noun is tied to the noun,

say "[The noun] and [the second noun] aren't tied together in the first place." instead.

Carry out untying it from:

now the noun is not tied to the second noun.

Report untying it from:

say "Untied."