Scroll Thief — 86 of 138

Part 3 - The Adventurer Himself/Herself

The Adventurer is a person in the Splendid Cavern. "[if neutral]In the darkness you see an adventurer holding a bright carbide lamp[else if scared]A bedraggled and weary-looking adventurer stands here, looking panicked and terrified[else if friendly][The Adventurer] is standing here, smiling frequently[else if obedient][The Adventurer] is standing here, awaiting a command[else if Act 1 is happening][The Adventurer] is looking at you uncertainly, not looking particularly obedient any more[otherwise][The Adventurer] is standing here, looking less than pleased at your presence. [He] glares at you with thinly-veiled hostility[end if]."

When play begins: set the gender of the adventurer to feminine; if the player is female, set the gender of the adventurer to masculine. [1]

The description of the Adventurer is "[adventurer desc][p]".

To say adventurer desc:

say "[regarding the Adventurer][He] [if the Adventurer is neutral]appears to be[else]is[end if] a few inches taller than you, and a good deal stronger. [r]";

say "[Her] hair is short and unruly, constantly getting in [her] eyes. It might be brown or black[--][r]";

if the Adventurer is neutral:

say "you can't tell. In the darkness of the cave, [her] eyes seem to glow with light.";

otherwise:

say "the dirt from the cave makes it hard to tell.";

say "[He] is carrying [a list of things carried by the Adventurer], and wearing thick padded clothing with straps and metal rings attached to it. It must serve some sort of magical purpose, although you can't think what that would be.[r]";

Every turn when the player can see the examined neutral adventurer: say "[The Adventurer] [one of]stares at the mirror, but doesn't seem to see you[or]consults [her] map, turning slowly in place[or]is apparently deep in thought[or]rummages through [her] possessions[or]is making furious pencil marks on a map[at random]."

Adventurer-puzzle is a puzzling scene with puzzle description "interacting with the Adventurer". The adventurer-puzzle begins when the Adventurer is examined. The adventurer-puzzle ends when the adventurer is obedient.

The dusty mirror can be clean or dirty. The dusty mirror is dirty.

Instead of examining the dirty dusty mirror:

say "You can't see anything through the dust."

Instead of rubbing the dirty dusty mirror:

take full time;

say "You rub some dirt away.";

now the dusty mirror is clean.

Instead of rubbing the clean dusty mirror:

say "The mirror is already clear enough to see through, and you don't have the time to really clean it up."

After casting lesoch at the location of the dusty mirror when the dusty mirror is dirty:

say "The wind does seem to have swept much of the dust from the mirror.";

now the dusty mirror is clean;

continue the action.

The adventurer can be neutral, obedient, scared, suspicious, or friendly (this is her disposition). The adventurer is neutral.

Persuasion rule for asking the adventurer to try doing something:

if the adventurer is scared:

say "[The adventurer] looks nervous and eyes you warily, but doesn't respond.";

take full time;

persuasion fails;

if the adventurer is suspicious:

say "[one of]'No.'[p]What? The [i]serage[/i] spell is supposed to force complete obedience.[or]'No, I won't.'[p]Something's clearly gone horribly wrong here.[or][The Adventurer] laughs angrily. 'Do you think your spell still binds me?'[p]The spell has worn off? That quickly?[p]'I'm done here. I have what I need. Now send me back.'[or][The Adventurer] doesn't seem likely to listen to you at this point.[stopping]";

take full time;

persuasion fails;

if the adventurer is friendly:

persuasion succeeds;

if the adventurer is obedient:

now the adventurer's last command is the saved command;

persuasion succeeds;

say "[The adventurer] whips around. 'Who said that?'"; [This happens if the Adventurer is still in the cave.]

take full time;

persuasion fails.